# Maintainer: Jesus E. <heckyel@riseup.net>

pkgname=goxel
pkgver=0.11.0
pkgrel=1
pkgdesc="Free and libre 3D program that lets you create voxel volumes"
arch=('i686' 'x86_64')
url='https://goxel.xyz/'
license=('GPL-3')
depends=('glfw' 'gtk')
makedepends=('scons' 'python-setuptools')
source=("${pkgname}-${pkgver}.tar.gz::https://github.com/guillaumechereau/${pkgname}/archive/v${pkgver}.tar.gz")
sha512sums=('548b718f56d7a8e2e16ede35252b6cf86de4acaf73bda16d01571c8487ac6a02d4ac21c96597f447c3b34774d84a4be63c1ecc89e5758122cd9942ec4bf7a7fc')

prepare() {
  cd ${pkgname}-${pkgver}

  # hack for the imgui.ini file that is placed directly in the home directory
  # bug report: https://github.com/guillaumechereau/goxel/issues/250
  sed -i 's#"imgui.ini"#".goxelrc"#g' ext_src/imgui/imgui.cpp

  # fix application shortcut file
  sed -i 's#applications/goxel.desktop#applications/io.github.guillaumechereau.Goxel.desktop#g' Makefile
  sed -i 's#\${SNAP}/icon.png#goxel#;s#Name=goxel#Name=Goxel#' snap/gui/${pkgname}.desktop
}

build() {
  cd ${pkgname}-${pkgver}
  scons mode=release werror=n
}

package() {
  cd ${pkgname}-${pkgver}

  make DESTDIR=${pkgdir} PREFIX=/usr install

  # dix binary file permission
  chmod -v +x ${pkgdir}/usr/bin/${pkgname}

  install -Dm644 COPYING -t ${pkgdir}/usr/share/licenses/${pkgname}
}