# Maintainer: Jesus E. <heckyel@riseup.net>

pkgname=gnustep-make
pkgver=2.8.0
_debver=2.8.0
_debrel=1
pkgrel=2
pkgdesc='The GNUstep make package'
arch=('i686' 'x86_64')
url="http://www.gnustep.org/"
license=('GPL-3')
groups=('gnustep-core')
backup=('etc/GNUstep/GNUstep.conf')
makedepends=('quilt')
source=("https://github.com/gnustep/tools-make/archive/make-${pkgver//./_}.tar.gz"
        "https://deb.debian.org/debian/pool/main/g/gnustep-make/gnustep-make_${_debver}-${_debrel}.debian.tar.xz")
sha512sums=('e31a018317fc2e8b93271a93a7b61fbcb06f1f5aa75a382a098434eb7b9d88493bac6a5bf80534077a17a58be7709b3d696f0f3470efb0cdf6d7277046444f2d'
            '9f27f9bfcc4b6a69c9fdd894165aacc0b3aefe3521395d89a9387c25619bbb8d7324c01cb7340810f603d2a23696dbb4645fae912038f812706eec99d8b65d7b')

prepare() {
  cd "$srcdir"/tools-make-make-${pkgver//./_}

  if [[ ${pkgver%.*} = ${_debver%.*} ]]; then
    # Debian patches
    export QUILT_PATCHES=debian/patches
    export QUILT_REFRESH_ARGS='-p ab --no-timestamps --no-index'
    export QUILT_DIFF_ARGS='--no-timestamps'

    mv "$srcdir"/debian .

    quilt push -av
  fi

  for i in GNUSTEP_SYSTEM_ADMIN_TOOLS GNUSTEP_NETWORK_ADMIN_TOOLS GNUSTEP_LOCAL_ADMIN_TOOLS; do
    sed -i "s|@$i@|/usr/bin|g" GNUstep{,-strict-v2}.conf.in filesystem.{sh,csh,make}.in
  done
}

build() {
  cd "$srcdir"/tools-make-make-${pkgver//./_}

  ./configure \
    --prefix=/usr \
    --sysconfdir=/etc/GNUstep \
    --enable-native-objc-exceptions
  make
}

package() {
  cd "$srcdir"/tools-make-make-${pkgver//./_}

  make DESTDIR="$pkgdir" install
  install -Dm644 COPYING -t "${pkgdir}/usr/share/licenses/$pkgname"
}