# Maintainer: Jesus E. <heckyel@riseup.net>

pkgname=gnuplot
pkgver=5.4.1
_debver=$pkgver
_debrel=1
pkgrel=2
pkgdesc="Plotting package which outputs to X11, PostScript, PNG, GIF, and others"
arch=('i686' 'x86_64')
url='http://www.gnuplot.info'
license=('GPL-2')
depends=('readline' 'gd' 'wxgtk3' 'cairo' 'libjpeg-turbo' 'lua' 'qt-svg' 'gnutls' 'libcerf')
makedepends=('qt-tools' 'quilt')
source=("https://downloads.sourceforge.net/sourceforge/$pkgname/${pkgname}-${pkgver}.tar.gz"
        "https://deb.debian.org/debian/pool/main/g/gnuplot/gnuplot_${_debver}+dfsg1-${_debrel}+deb11u1.debian.tar.xz"
        "lua53_compat.patch")
sha512sums=('2371830636d4c9ee93e9d6566dc2889e96ece3660b63ef4cfb6514e233510e5abaf4f93863bbe9a418f11db8e3b12a15242556aae52bb69591ad7d26e6581121'
            'ead10a5e98b32e0c968449b3baa0e30e4299976248dd36755f702e174132a932dc0f66ed04f8646abf0ce84fdd30965e3dc805138870142c590f716015f56ebf'
            '410b82ff7e4759ec77c446dcae33a8b14634d1627d2ce3fc43a5ce25dd071d80e7fee8232366d56bce57b12807cabb53e2a4eed4e9545be2358c510b3c7528e7')

prepare() {
  cd ${pkgname}-${pkgver}
  if [[ ${pkgver%.*} = ${_debver%.*} ]]; then
    # Debian patches
    export QUILT_PATCHES=debian/patches
    export QUILT_REFRESH_ARGS='-p ab --no-timestamps --no-index'
    export QUILT_DIFF_ARGS='--no-timestamps'

    mv "$srcdir"/debian .

    quilt push -av
  fi

  # fix default source location; use the GDFONTPATH variable to modify at runtime
  sed -i 's|/usr/X11R6/lib/X11/fonts/truetype|/usr/share/fonts/TTF|' src/variable.c

  sed -i -e 's|/usr/X11R6/lib/X11/fonts/Type1|/usr/share/fonts/Type1|' \
  -e 's|$(X11ROOT)/X11R6/lib/X11/fonts/Type1|$(X11ROOT)/usr/share/fonts/Type1|' \
  src/variable.c

  patch -p1 < "$srcdir"/lua53_compat.patch
}

build() {
  cd ${pkgname}-${pkgver}
  MAKEINFO=/usr/bin/makeinfo WX_CONFIG=/usr/bin/wx-config-gtk3 ./configure --prefix=/usr \
              --with-gihdir=/usr/share/gnuplot \
              --with-readline=gnu \
              --with-bitmap-terminals \
              --with-wx-single-threaded
  make
}

package() {
  cd ${pkgname}-${pkgver}
  make DESTDIR="${pkgdir}" install
  install -Dm644 debian/copyright -t "${pkgdir}/usr/share/licenses/$pkgname"
}