# Maintainer: Jesus E. <heckyel@riseup.net>

pkgname=gltron
pkgver=0.70
_debver=$pkgver
_debrel=12.2
pkgrel=1
pkgdesc="A free software lightcycle game with a nice 3D perspective"
arch=('i686' 'x86_64')
url='http://www.gltron.org'
license=('GPL-2')
depends=('mesa-libgl' 'gcc-libs' 'smpeg' 'sdl' 'sdl_sound' 'libpng' 'glu')
makedepends=('quilt')
options=('!makeflags')
groups=('games')
source=("https://deb.debian.org/debian/pool/main/g/gltron/gltron_${pkgver}final.orig.tar.gz"
        "https://deb.debian.org/debian/pool/main/g/gltron/gltron_${_debver}final-${_debrel}.debian.tar.xz")
sha512sums=('297708a145d995bfd186f1745ffa674ab44238e8c2fb627245de3c1602f578afdd9223fae696107769b3b29da476cd9623ee37183618bfb13a9a9cfa59e41bf2'
            '5602a47461c1deefd59d3f12f86fc11422586914b52cd8a155b7a0f6f124136494c0b300ffe779f9208a8268fbfeff9f81e444d78c7723baa999f9d486d68748')

prepare() {
  cd "${srcdir}"/$pkgname-$pkgver
  if [[ ${pkgver%.*} = ${_debver%.*} ]]; then
    # Debian patches
    export QUILT_PATCHES=debian/patches
    export QUILT_REFRESH_ARGS='-p ab --no-timestamps --no-index'
    export QUILT_DIFF_ARGS='--no-timestamps'

    mv "$srcdir"/debian .

    quilt push -av
  fi
  autoreconf -vfi
}


build() {
  cd "${srcdir}"/$pkgname-$pkgver
  ./configure \
    --prefix=/usr \
    --bindir=/usr/games \
    --datadir=/usr/share/games \
    --mandir=/usr/share/man \
    --infodir=/usr/share/info \
    --enable-network \
    --enable-warn=off
  make
}

package() {
  cd "${srcdir}"/$pkgname-$pkgver
  make DESTDIR="${pkgdir}" install

  install -Dm644 debian/$pkgname.xpm -t "${pkgdir}"/usr/share/pixmaps
  install -Dm644 debian/$pkgname.desktop -t "${pkgdir}"/usr/share/applications
  install -Dm644 COPYING -t "${pkgdir}"/usr/share/licenses/$pkgname
}