# Maintainer: Jesus E. <heckyel@riseup.net>

pkgname=glslang
pkgver=8.13.3743
_debver=$pkgver
_debrel=1
pkgrel=2
pkgdesc="OpenGL and OpenGL ES shader front end and validator"
arch=('i686' 'x86_64')
url='https://github.com/KhronosGroup/glslang'
license=('Modified-BSD')
depends=('gcc-libs' 'spirv-tools' 'python')
makedepends=('cmake' 'ninja' 'quilt')
options=('staticlibs')
source=(${pkgname}-${pkgver}.tar.gz::https://github.com/KhronosGroup/glslang/archive/${pkgver}.tar.gz
        https://deb.debian.org/debian/pool/main/g/glslang/glslang_${_debver}-${_debrel}~bpo10+1.diff.gz)
sha512sums=('19169c4ffa511113978af8e8efc57b290d4aa962a4c2429dbea1af72204787c6ce20ffbbb452dc04bef5416e00510819d84463a2e76295b9a59b409e12af6792'
            'e5a1e452c26aa08f1583192d000af51b8f8212e069ff40fa12b38da22f21cf7fb5f54cdb2a03c0d85af3ad4ef75d38f3ad41ca05d95e08ce8658556cc0f0fa28')

prepare() {
  cd ${pkgname}-${pkgver}
  if [[ ${pkgver%.*} = ${_debver%.*} ]]; then
    # Debian patches
    export QUILT_PATCHES=debian/patches
    export QUILT_REFRESH_ARGS='-p ab --no-timestamps --no-index'
    export QUILT_DIFF_ARGS='--no-timestamps'

    patch -p1 -i "$srcdir"/glslang_${_debver}-${_debrel}~bpo10+1.diff

    quilt push -av
  fi
}

build() {
  cd ${pkgname}-${pkgver}
  mkdir -p build-{shared,static}
  (cd build-shared
    cmake .. \
      -GNinja \
      -DCMAKE_INSTALL_PREFIX=/usr \
      -DCMAKE_BUILD_TYPE=Release \
      -DBUILD_SHARED_LIBS=ON \
      -Wno-dev
    ninja
  )
  (cd build-static
    cmake .. \
      -GNinja \
      -DCMAKE_INSTALL_PREFIX=/usr \
      -DCMAKE_BUILD_TYPE=Release \
      -DBUILD_SHARED_LIBS=OFF \
      -Wno-dev
    ninja
  )
}

package() {
  cd ${pkgname}-${pkgver}
  DESTDIR="${pkgdir}" ninja -C build-shared install
  DESTDIR="${pkgdir}" ninja -C build-static install

  install -Dm644 LICENSE.txt -t "${pkgdir}"/usr/share/licenses/${pkgname}

  cd "${pkgdir}"/usr/lib
  for lib in *.so; do
    ln -sf "${lib}" "${lib}.0"
  done
}