# Maintainer: Jesus E. <heckyel@riseup.net>

pkgname=glibmm
pkgver=2.64.2
_debver=$pkgver
_debrel=2
pkgrel=2
pkgdesc="C++ bindings for GLib"
url='https://www.gtkmm.org/'
arch=('i686' 'x86_64')
license=('LGPL-2.1')
depends=('glib2' 'libsigc++')
makedepends=('mm-common' 'perl-xml-parser' 'clang' 'meson' 'quilt')
options=(!emptydirs)
source=("https://ftp.gnome.org/pub/GNOME/sources/${pkgname}/${pkgver:0:4}/${pkgname}-${pkgver}.tar.xz"
        "https://deb.debian.org/debian/pool/main/g/glibmm2.4/glibmm2.4_${_debver}-${_debrel}.debian.tar.xz")
sha512sums=('0130af9a16981a54630150db6f4b1a95458d72d650c5e4781ee97ce624ec98c600b79ebf234d212e025781453fd11d78b9e8273235ffa143397423418fe970cc'
            '7fe57c06f423ac785f24dbff97954e256978e65035be7625bb76aaa5424514b99b6cf7b5406392e3b998b66d8a0b24f1f637412a2da583e4fe95710e0bfa8a40')

prepare() {
  cd $pkgname-$pkgver
  if [[ ${pkgver%.*} = ${_debver%.*} ]]; then
    # Debian patches
    export QUILT_PATCHES=debian/patches
    export QUILT_REFRESH_ARGS='-p ab --no-timestamps --no-index'
    export QUILT_DIFF_ARGS='--no-timestamps'

    mv "$srcdir"/debian .

    quilt push -av
  fi
}

build() {
  hyperbola-meson $pkgname-$pkgver build -D maintainer-mode=true
  ninja -C build
}

package() {
  DESTDIR="$pkgdir" meson install -C build
  install -Dm644 $srcdir/$pkgname-$pkgver/COPYING -t $pkgdir/usr/share/licenses/$pkgname
}