# Maintainer: Jesus E. <heckyel@riseup.net>

pkgname=giflib
pkgver=5.1.9
_debver=5.1.9
_debrel=1
pkgrel=1
pkgdesc='Library for reading and writing gif images'
url='http://giflib.sourceforge.net/'
arch=('i686' 'x86_64')
license=('Expat')
depends=('glibc')
makedepends=('xmlto' 'docbook-xml' 'docbook-xsl' 'quilt')
source=(https://downloads.sourceforge.net/project/giflib/${pkgname}-${pkgver}.tar.gz
        https://deb.debian.org/debian/pool/main/g/giflib/giflib_$_debver-$_debrel.debian.tar.xz
        giflib-5.1.9-fix-missing-quantize-API-symbols.patch
        giflib-5.1.9-make-flags.patch)
sha512sums=('b6350b39755e3eeba58b5fccf319bbaeee2db6564e13c8ce44d3652cc32d243c391def74b6b1529bc5e0d4573eff94b2ffa5faa90fc564a049122d3e23f1d184'
            '9d5f2dceb15b36446a41a21872e68d871c9e97a3b2ee7fbdca8fefe0eff85736a6872ea9fe9227e72851eef4b119e037e04f69360c6d9d7afb389b4cd0007923'
            '5de1e8724f5221fa3637b4e6a482f650f7608673e2c9200233290018ec8a0bf1beea049b3979b5f57dbf2b2a5fda409324e636e9af10582fd01c71d92d4de3b3'
            'b9afd436c31b971087485c7b476f796817e6ee4f237ef8a0e61e47f8ac59fbe5e673d7194895fcc9aafbb79f133469d27c2f69041ae0cccd9acb78667c0222dd')

prepare() {
  cd ${pkgname}-${pkgver}
  if [[ ${pkgver%.*} = ${_debver%.*} ]]; then
    # Debian patches
    export QUILT_PATCHES=debian/patches
    export QUILT_REFRESH_ARGS='-p ab --no-timestamps --no-index'
    export QUILT_DIFF_ARGS='--no-timestamps'

    mv "$srcdir"/debian .

    quilt push -av
  else
    patch -Np1 < ../giflib-5.1.9-fix-missing-quantize-API-symbols.patch
  fi
  patch -Np1 < ../giflib-5.1.9-make-flags.patch
}

build() {
  cd ${pkgname}-${pkgver}
  make
}

check() {
  cd ${pkgname}-${pkgver}
  make check
}

package() {
  cd ${pkgname}-${pkgver}
  make PREFIX=/usr DESTDIR="${pkgdir}" install
  install -Dm 644 COPYING -t "${pkgdir}/usr/share/licenses/${pkgname}"
}

# vim: ts=2 sw=2 et: