# Maintainer: Jesus E. <heckyel@riseup.net>

pkgname=frozen-bubble
pkgver=2.212
_debver=$pkgver
_debrel=9
pkgrel=1
pkgdesc="A free and libre game in which you throw colorful bubbles and build groups to destroy the bubbles"
arch=('i686' 'x86_64')
url='http://www.frozen-bubble.org'
license=('GPL-2')
depends=('perl-sdl' 'perl-ipc-system-simple' 'perl-compress-bzip2' 'perl-file-which')
makedepends=('perl-file-slurp' 'perl-locale-maketext-lexicon' 'perl-module-build')
options=('!emptydirs')
groups=('games')
source=("${pkgname}-${pkgver}.tar.gz::https://deb.debian.org/debian/pool/main/f/frozen-bubble/frozen-bubble_${pkgver}.orig.tar.gz"
        "https://deb.debian.org/debian/pool/main/f/frozen-bubble/frozen-bubble_${_debver}-${_debrel}.debian.tar.xz")
sha512sums=('577e3e59d75b33b7b0dc0766e099ed42d6c865261b3aac3b9697563d2008de46b2574d9a7c1af24cd2e0e56edd593cf856a4ceff5411ac8d33fa61dc00945a2e'
            '9e378532f6d63ed8c0c541c3f50844a7af74347038340b36db5cbb1c45553edd909d283fbf15bfda6dbf77fed57fe390d78257de72409fc48c2ee02a6861226e')

prepare() {
  mv "Games-FrozenBubble-$pkgver" "$pkgname-$pkgver"
  cd "$srcdir/$pkgname-$pkgver"

  if [[ ${pkgver%.*} = ${_debver%.*} ]]; then
    # Debian patches
    export QUILT_PATCHES=debian/patches
    export QUILT_REFRESH_ARGS='-p ab --no-timestamps --no-index'
    export QUILT_DIFF_ARGS='--no-timestamps'

    mv "$srcdir"/debian .

    quilt push -av
  fi

  sed -e 's|-Werror||' -i inc/My/Builder.pm
}

build() {
  cd "$srcdir/$pkgname-$pkgver"
  unset CFLAGS

  # install module in vendor directories
  perl Build.PL installdirs=vendor
  perl Build
}

package() {
  cd "$srcdir/$pkgname-$pkgver"
  perl Build install destdir="$pkgdir"

  # correct package-structure
  mv "$pkgdir/usr/bin" "$pkgdir/usr/games"
  install -d "$pkgdir/usr/share/games"
  mv "$pkgdir/usr/lib/perl5/auto/share/dist/Games-FrozenBubble" "$pkgdir/usr/share/games/frozen-bubble"

  # icon, desktop-shortcut and license
  install -Dm644 debian/$pkgname.xpm -t "$pkgdir/usr/share/pixmaps"
  install -Dm644 debian/$pkgname.desktop -t "$pkgdir/usr/share/applications"
  install -Dm644 COPYING -t "$pkgdir/usr/share/licenses/$pkgname"
}