# Maintainer: Jesus E. <heckyel@riseup.net>

_name=FreeRDP
pkgname=freerdp
pkgver=2.3.0
_debver=$pkgver
_debrel=2
pkgrel=4
pkgdesc="Free and libre implementation of the Remote Desktop Protocol (RDP)"
arch=('i686' 'x86_64')
url='https://www.freerdp.com/'
license=('Apache-2.0')
depends=('gstreamer' 'gst-plugins-base-libs' 'libcups' 'ffmpeg' 'icu' 'libjpeg-turbo' 'libusb'
         'libx11' 'libxcursor' 'libxext' 'libxdamage' 'libxfixes' 'libxkbcommon' 'libxi'
         'libxinerama' 'libxkbfile' 'libxrandr' 'libxrender' 'libxtst' 'libressl')
makedepends=('cmake' 'docbook-xsl' 'krb5' 'xmlto' 'xenocara-proto' 'quilt')
if [ $(uname -s) = HyperbolaBSD ]; then
  _alsa=OFF
  _oss=ON
else
  _alsa=ON
  _oss=OFF
  depends+=(alsa-lib)
fi
source=($pkgname-$pkgver.tar.gz::https://github.com/$pkgname/$pkgname/archive/$pkgver.tar.gz
        https://security.debian.org/debian-security/pool/updates/main/f/freerdp2/freerdp2_$_debver+dfsg1-$_debrel+deb11u3.debian.tar.xz
        manpage_formatting.patch)
sha512sums=('e1e1fd54c51b3404c188b621b15ddcbef279868e8e10233b64fd281ef0f03b05545e32b21520f9260141e06ee9864fbb6b6489c22ab99642d2f3bb50a9967731'
            '59cdc8409c9140ce47b357fde56bba84699e7d60dc5101492250ee3e7bace814cd478ae78631a6099f3d218b28111910ae38ca8a9e1c7dd83dc4f842f97da029'
            'd960e042d1527b5d5721136b6b20fc36f65beafd010581ea5b908668537fe9fe622de6689a29c0274b0d6f1e513615f0d02e56c1d1d1e613d093e145d39af8d7')

prepare() {
  cd "$srcdir/$_name-$pkgver"
  if [ ${pkgver%.*} = ${_debver%.*} ]; then
    # Debian patches
    export QUILT_PATCHES='debian/patches'
    export QUILT_REFRESH_ARGS='-p ab --no-timestamps --no-index'
    export QUILT_DIFF_ARGS='--no-timestamps'

    mv "$srcdir/debian" .

    quilt push -av
  fi

  # fix man page formatting
  patch -p1 -i $srcdir/manpage_formatting.patch
}

build() {
  cmake -DCMAKE_INSTALL_PREFIX=/usr \
        -DCMAKE_INSTALL_LIBDIR=lib \
        -DCMAKE_BUILD_TYPE=None \
        -DPROXY_PLUGINDIR=/usr/lib/freerdp2/server/proxy/plugins \
        -DWITH_DSP_FFMPEG=ON \
        -DWITH_FFMPEG=ON \
        -DWITH_PULSE=OFF \
        -DWITH_LIBSYSTEMD=OFF \
        -DWITH_WAYLAND=OFF \
        -DWITH_MBEDTLS=OFF \
        -DWITH_ALSA=$_alsa \
        -DWITH_OSS=$_oss \
        -DWITH_CUPS=ON \
        -DWITH_PCSC=OFF \
        -DWITH_GSSAPI=OFF \
        -DWITH_ICU=ON \
        -DWITH_JPEG=ON \
        -DWITH_SERVER=ON \
        -DWITH_SWSCALE=ON \
        -DWITH_CHANNELS=ON \
        -DWITH_CLIENT_CHANNELS=ON \
        -DWITH_SERVER_CHANNELS=ON \
        -DCHANNEL_URBDRC_CLIENT=ON \
        -Wno-dev \
        -B $srcdir/build \
        -S $srcdir/$_name-$pkgver
  make -C build
}

package() {
  make DESTDIR="$pkgdir" install -C "$srcdir/build"
  install -Dvm644 "$srcdir/$_name-$pkgver/LICENSE" -t "$pkgdir/usr/share/licenses/$pkgname"
}