# Maintainer: Jesus E. <heckyel@riseup.net>

pkgname=fontforge
pkgver=20230101
_debver=$pkgver
_debrel=1.1
pkgrel=3
pkgdesc="Outline and bitmap font editor"
url='https://fontforge.github.io/'
arch=('i686' 'x86_64')
license=('GPL-3' 'GPL-2' 'Simplified-BSD' 'Modified-BSD' 'OFL-1.1' 'Apache-2.0' 'CC0-1.0' 'custom:Bitstream-Vera')
depends=('libtool' 'pango' 'giflib' 'libtiff' 'libxml2' 'libspiro' 'libxi' 'python'
         'potrace' 'libuninameslist' 'gtk')
makedepends=('cmake' 'git-legacy' 'python-sphinx' 'quilt')
source=("${pkgname}-${pkgver}.tar.xz::https://deb.debian.org/debian/pool/main/f/fontforge/fontforge_${pkgver}~dfsg.orig.tar.xz"
        "https://deb.debian.org/debian/pool/main/f/fontforge/fontforge_${_debver}~dfsg-${_debrel}~deb12u1.debian.tar.xz")
sha512sums=('a6283fc0b6f5f9b436be3fed502e5381e90a1b76e2c1b01b043c64add183a4825005fc7d06b063682ffa635f7b05a9aefb0815b2f979cc48672cade48cf3592d'
            'ea992ccc1b7ca2d7f30fe784bfa0b8cc8dbbe673f80378a089ef3a811770ec52eb00ca0e9de9f168e9b04d2e32b3cc2fc70ef088b1e75fe820f42a5eb6c19d8a')

prepare() {
  cd $pkgname-$pkgver
  if [[ $pkgver = ${_debver%~*} ]]; then
    # Debian patches
    export QUILT_PATCHES=debian/patches
    export QUILT_REFRESH_ARGS='-p ab --no-timestamps --no-index'
    export QUILT_DIFF_ARGS='--no-timestamps'

    mv "$srcdir"/debian .

    quilt push -av
  fi
}

build() {
  cd $pkgname-$pkgver
  cmake \
    -B build \
    -DCMAKE_BUILD_TYPE=Release \
    -DCMAKE_INSTALL_PREFIX=/usr \
    -DENABLE_MAINTAINER_TOOLS=TRUE \
    -DENABLE_FONTFORGE_EXTRAS=TRUE \
    -DUNIX=TRUE \
    -DENABLE_X11=ON \
    -DENABLE_WOFF2=OFF
  make -C build
}

package() {
  cd $pkgname-$pkgver
  make DESTDIR=$pkgdir -C build install
  for i in LICENSE COPYING.gplv3 debian/copyright; do
    install -Dm644 $i $pkgdir/usr/share/licenses/$pkgname/$i
  done
}