# Maintainer: Jesus E. <heckyel@riseup.net>

pkgname=fluxbox
pkgver=1.3.5
_debver=1.3.5
_debrel=2
pkgrel=2
pkgdesc="A lightweight and highly-configurable window manager"
arch=('i686' 'x86_64')
url="http://www.fluxbox.org"
license=('Expat')
makedepends=('quilt')
depends=('libxft' 'libxpm' 'libxinerama' 'libxrandr' 'imlib2' 'fribidi')
optdepends=('xenocara-xmessage: for using the fbsetbg and fluxbox-generate_menu utilities')
options=('!makeflags')
source=("https://sourceforge.net/projects/${pkgname}/files/${pkgname}/${pkgver}/${pkgname}-${pkgver}.tar.gz"
        "https://deb.debian.org/debian/pool/main/f/fluxbox/fluxbox_$_debver-$_debrel.debian.tar.xz"
        'libre.patch'
        'fluxbox.desktop')
sha512sums=('9f787cf2f41627e0e371c751919f552859bd431644393311ea0f4bc3231b371d65016a3543e745526012eb0d6775bd2fb0511b28066f1071639c7ace99b8dbc0'
            '9c6da46961e1078b57be14ff61427b594cbe2b264e54b0714c8cbadcd517021e96d09fe5fc7e00e1e9ce62d95ca54ac8b7bf5389f9ca25c165c674672a9a017a'
            '3bf4fd7e6055eea2ffff9e9e1dbf57160a5992963724ad96afa94d53d870a6b26059ab083b8278da523766886082237e0fcf04f82f6cb2c46fb4844c4e23ebcf'
            '89e81253519d52cf82c2667f81887906153ff97a3017e7b9ef04faa8d06c6bf2eb55f66f636597eff597eba6cc82b47ba8db40e45e40863ec87f4f2cbb4019d8')

prepare() {
  cd ${pkgname}-${pkgver}

  if [[ ${pkgver%.*} = ${_debver%.*} ]]; then
    # Debian patches
    export QUILT_PATCHES=debian/patches
    export QUILT_REFRESH_ARGS='-p ab --no-timestamps --no-index'
    export QUILT_DIFF_ARGS='--no-timestamps'

    mv "$srcdir"/debian .

    # Doesn't apply and seems unimportant
    rm -v debian/patches/debian-conffile-location.diff || true
    rm -v debian/patches/fix-xterm-keybinding.patch || true

    quilt push -av
  fi

  # Remove nonfree apps and nonsupport apps
  patch -Np1 -i "${srcdir}/libre.patch"
}

build() {
  cd ${pkgname}-${pkgver}

  ./configure --prefix=/usr --enable-imlib2 --enable-nls --enable-xft --enable-xinerama
  make
}

package() {
  cd ${pkgname}-${pkgver}

  make DESTDIR="${pkgdir}" install
  install -D -m644 "${srcdir}/fluxbox.desktop" "${pkgdir}/usr/share/xsessions/fluxbox.desktop"
  install -D -m644 COPYING "${pkgdir}/usr/share/licenses/${pkgname}/COPYING"
}