# Maintainer: Jesus E. <heckyel@riseup.net>

pkgname=fluidsynth
pkgver=2.1.7
_debver=$pkgver
_debrel=1.1
pkgrel=5
pkgdesc="A real-time software synthesizer based on the SoundFont 2 specifications"
arch=('i686' 'x86_64')
url='https://www.fluidsynth.org/'
license=('LGPL-2.1')
depends=('alsa-lib' 'glibc' 'sdl2' 'jack' 'ladspa' 'libinstpatch' 'libsndfile' 'portaudio')
makedepends=('cmake' 'doxygen' 'glib2' 'readline' 'quilt')
backup=('etc/conf.d/$pkgname')
install=${pkgname}.install
source=("$pkgname-$pkgver.tar.gz::https://github.com/${pkgname}/${pkgname}/archive/v$pkgver.tar.gz"
        https://deb.debian.org/debian/pool/main/f/fluidsynth/fluidsynth_$_debver-$_debrel.debian.tar.xz
        fluidsynth.initd
        fluidsynth.confd
        fluidsynth.run
        fluidsynth.conf)
sha512sums=('22ab9bb3c5d5e619c0624ced2031b23d9d68cf9ffd6da40087aa0049f486b8c6201ff19605fc73fa642358bec31c18bb43683a8b0d603b198626d9a23721bcd6'
            'c6c9ac2a8c41bf25031b8c2bae0e223955ba697fcacd8670eb7709640bd069e7783e6e28adbc85152a3e1fbc3cd14ba290403154437fb1f9b1cc30a9ecaf0a4f'
            '35124b93294e379f1aaf8d66f3159fe5451f12f89c22111d7b6fb85ef839f1411ee29cd0756811d02a05ed9f7fe9422234f12b6626e0fff3cbce395d7cb3665a'
            'c4174b68572dc0a06bc770f6de53d5ed3c765c394d17a95fa8c4eb89cbcfcb9e651a6d3607fd4876ef82c5956c9371516ca0e9570e4314a0ea64aac4c4d90fe6'
            '501d4399cac0938d1373fc025fba01e24eb47ab2671886f4701253ca1b221331b0b127e60d1c38cc4757cbd64b9d67f4996dfa09854887907e78eda1dfbca78f'
            'c4174b68572dc0a06bc770f6de53d5ed3c765c394d17a95fa8c4eb89cbcfcb9e651a6d3607fd4876ef82c5956c9371516ca0e9570e4314a0ea64aac4c4d90fe6')

prepare() {
  cd "${pkgname}-${pkgver}"
  if [[ ${pkgver%.*} = ${_debver%.*} ]]; then
    # Debian patches
    export QUILT_PATCHES=debian/patches
    export QUILT_REFRESH_ARGS='-p ab --no-timestamps --no-index'
    export QUILT_DIFF_ARGS='--no-timestamps'

    mv "$srcdir"/debian .

    quilt push -av
  fi
}

build() {
  cd "${pkgname}-${pkgver}"
  cmake -DCMAKE_INSTALL_PREFIX=/usr \
        -DCMAKE_BUILD_TYPE='None' \
        -BUILD_SHARED_LIBS=ON \
        -Denable-ladspa=ON \
        -Denable-portaudio=ON \
        -Denable-sdl2=ON \
        -Denable-pkgconfig=ON \
        -Denable-pulseaudio=OFF \
        -Denable-dbus=OFF \
        -DLIB_SUFFIX="" \
        -Wno-dev \
        -B build \
        -S .
  make -C build VERBOSE=1
}

package() {
  cd "${pkgname}-${pkgver}"
  make -C build DESTDIR="$pkgdir" install

  # services for hyperrc and runit
  install -Dm 755 "${srcdir}/${pkgname}.initd" "${pkgdir}/etc/init.d/${pkgname}"
  install -Dm 644 "${srcdir}/${pkgname}.confd" "${pkgdir}/etc/conf.d/${pkgname}"
  install -Dm 755 "$srcdir/${pkgname}.run" "$pkgdir/etc/sv/${pkgname}/run"
  install -Dm 644 "$srcdir/${pkgname}.conf" "$pkgdir/etc/sv/${pkgname}/conf"

  # docs
  install -vDm 644 {AUTHORS,ChangeLog,{CONTRIBUTING,README}.md,THANKS,TODO} -t "${pkgdir}/usr/share/doc/${pkgname}"

  # license
  install -vDm 644 LICENSE -t "${pkgdir}/usr/share/licenses/${pkgname}"
}