# Maintainer: Jesus E. <heckyel@riseup.net>

pkgname=flightgear
pkgver=2020.3.6
_pkgver=${pkgver%.*}
_debver=$pkgver
_debrel=1
pkgrel=3
pkgdesc="A free software, multi-platform flight simulator"
arch=('i686' 'x86_64')
url='https://www.flightgear.org/'
license=('GPL-2' 'LGPL-2' 'Modified-BSD' 'Public-Domain' 'Expat')
provides=('flightgear' 'flightgear-data')
conflicts=('flightgear' 'flightgear-data')
depends=('libxmu' 'libxi' 'zlib' 'openscenegraph' 'libxrandr' 'glu' 'openal' 'speex' 'sqlite' 'glew'
         'qt-svg' 'qt-quickcontrols' 'udns')
makedepends=('boost' 'cmake' 'mesa' 'sharutils' 'simgear' 'qt-tools' 'quilt')
groups=('games')
options=('makeflags')
source=("https://downloads.sourceforge.net/project/flightgear/release-${_pkgver}/${pkgname}-${pkgver}.tar.bz2"
        "https://security.debian.org/debian-security/pool/updates/main/f/flightgear/flightgear_${_debver}+dfsg-${_debrel}+deb11u1.debian.tar.xz"
        "https://downloads.sourceforge.net/project/flightgear/release-${_pkgver}/FlightGear-${pkgver}-data.tar.bz2")
sha512sums=('b0bfa6e02cf5c2e64aea85fb7433e583141471e15a7dff69dbc12c227835c6e52dcf5b2947a30847c2b291442878eee6265217311e441abb32c5f95bbf7df990'
            '1f328485c3103a6683720775a1bde76e1dc5de72cbff1b45e9c3e9e1013166a813f9a04355b75df8cc4c455252c5f47567832bf51ec61fcc584973083281b6d3'
            'd29ff4feb72be167b57b9baae461c810aef537085084bfb0c0ffbb2d1575ced38a951478fa1fd395c219919528af7e050a6c5199c337592cf607da5a3c682017')
noextract=("FlightGear-${pkgver}-data.tar.bz2")

prepare() {
  mkdir -p FlightGear-${pkgver}-data
  tar -xf  "FlightGear-${pkgver}-data.tar.bz2" --strip 1 \
      -C   "FlightGear-${pkgver}-data"

  cd "$srcdir"/flightgear-$pkgver
  if [[ ${pkgver%.*} = ${_debver%.*} ]]; then
    # Debian patches
    export QUILT_PATCHES=debian/patches
    export QUILT_REFRESH_ARGS='-p ab --no-timestamps --no-index'
    export QUILT_DIFF_ARGS='--no-timestamps'

    mv "$srcdir"/debian .

    # Doesn't apply
    rm -v debian/patches/Add_from_nasal_helper.patch || true

    quilt push -av
  fi
  sed -i 's|Exec=.*|Exec=fgfs --fg-root=/usr/share/games/flightgear/data|' package/org.flightgear.FlightGear.desktop
}

build() {
  cmake \
    -S flightgear-$pkgver \
    -Bbuild \
    -DCMAKE_BUILD_TYPE="Release" \
    -DCMAKE_VERBOSE_MAKEFILE=ON \
    -DCMAKE_INSTALL_PREFIX:PATH=/usr \
    -DCMAKE_INSTALL_BINDIR:PATH=games \
    -DFG_DATA_DIR:PATH=/usr/share/games/flightgear/data \
    -DENABLE_LARCSIM=ON \
    -DENABLE_UIUC_MODEL=ON \
    -DENABLE_QT=ON \
    -DSP_FDMS=ON \
    -DSYSTEM_SPEEX=ON \
    -DENABLE_SWIFT=OFF \
    -DUSE_DBUS=OFF \
    -Wno-dev
  make -C build
}

package() {
  make DESTDIR="$pkgdir" -C build install

  cd "$srcdir"/flightgear-$pkgver
  install -Dm644 debian/copyright -t "$pkgdir"/usr/share/licenses/$pkgname

  cd "$srcdir"
  mkdir -p "$pkgdir"/usr/share/games/flightgear
  mv ./FlightGear-${pkgver}-data "$pkgdir"/usr/share/games/flightgear/data
  chown -R root:games "$pkgdir"/usr/share/games/flightgear/data
}