# Maintainer: Jesus E. <heckyel@riseup.net>

pkgname=filezilla
pkgver=3.52.2
_debver=$pkgver
_debrel=3
pkgrel=2
pkgdesc="Fast and reliable FTP, FTPS and SFTP client"
url='https://filezilla-project.org/'
arch=('i686' 'x86_64')
license=('GPL-2')
depends=('xdg-utils' 'wxgtk3' 'libidn' 'hicolor-icon-theme' 'sqlite' 'gnutls' 'libfilezilla')
makedepends=('quilt')
source=(https://download.filezilla-project.org/client/FileZilla_${pkgver}_src.tar.bz2
        https://deb.debian.org/debian/pool/main/f/filezilla/filezilla_$_debver-$_debrel.debian.tar.xz)
sha512sums=('74abb78eaece5ffed044a88bdbbff7be0470e47868b806925ea5666d741370dff910d55849f6ad91fb57f8c1a33c461dc10c9f093d75e7a96ff0d909f3a8f131'
            '6372820728df7e2edc53b84eefa896c6e89797d08b8ecdde3fa3783707f4d781bb5059d337e28573889754307f42b1dce77d73d7b521158c2f1b515d150c5a7d')

prepare() {
  cd ${pkgname}-${pkgver}

  if [[ ${pkgver%.*} = ${_debver%.*} ]]; then
    # Debian patches
    export QUILT_PATCHES=debian/patches
    export QUILT_REFRESH_ARGS='-p ab --no-timestamps --no-index'
    export QUILT_DIFF_ARGS='--no-timestamps'

    mv "$srcdir"/debian .

    quilt push -av
  fi

  # removing problematic locales, incompatible with concurrent gettext-tiny
  rm ./locales/he_IL.po
  rm ./locales/ro_RO.po
  rm ./locales/ru.po
  rm ./locales/sk_SK.po
  rm ./locales/sl_SI.po
  rm ./locales/ta.po
  rm ./locales/th_TH.po
  rm ./locales/tr.po
  rm ./locales/uk_UA.po
  rm ./locales/vi_VN.po
  rm ./locales/zh_CN.po
  rm ./locales/zh_TW.po
}

build() {
  cd ${pkgname}-${pkgver}

  ./configure \
    --prefix=/usr \
    --disable-manualupdatecheck \
    --disable-autoupdatecheck \
    --with-pugixml=builtin \
    --with-dbus=no \
    --with-wx-config=/usr/bin/wx-config-gtk3
  make
}

package() {
  cd ${pkgname}-${pkgver}

  make DESTDIR="${pkgdir}" install
  install -Dm644 COPYING -t "${pkgdir}/usr/share/licenses/$pkgname"
}