# Maintainer: Jesus E. <heckyel@riseup.net>
# Controbutor (Arch): Baptiste Jonglez <archlinux at bitsofnetworks dot org>

pkgname=fig2dev
pkgver=3.2.8
_upstreamver=3.2.8a
_debver=3.2.8
_debrel=3
pkgrel=1
pkgdesc='Format conversion utility that can be used with xfig'
arch=('i686' 'x86_64')
url="http://mcj.sourceforge.net/"
license=('Expat')
depends=('libpng' 'libxpm' 'bc' 'netpbm' 'ghostscript')
makedepends=('quilt')
conflicts=('transfig')
replaces=('transfig')
provides=('transfig')
source=("https://downloads.sourceforge.net/mcj/${pkgname}-${_upstreamver}.tar.xz"
        "https://deb.debian.org/debian/pool/main/f/fig2dev/fig2dev_${_debver}-${_debrel}.debian.tar.xz"
        "LICENSE")
sha512sums=('b205a820743d38405d1348ccb926650e8279a3adad8b5e3ec262cbbfa570f9ff39ba366138256a6c494e5a6df66ca6ae1e59ac9c4ca37b354da6226c5ae700e8'
            '0c62c4dffd4abb04140f9d051a15f1cab72d95424224b9840a2420faae7d78fe5d5ffd7a812e9b89ab8089f905831c1c076b3f44a37a3e0ca7009089e060595e'
            'f9f359f83dd89f4877b4bdb846903398779a71682f3488f9383005f85dc57bde901ac5d7412a414eb26d4cf991ab2e6a376c388160ad0368e27f08a92e724142')

prepare() {
  cd "${pkgname}-${_upstreamver}"
  if [[ ${pkgver%.*} = ${_debver%.*} ]]; then
    # Debian patches
    export QUILT_PATCHES=debian/patches
    export QUILT_REFRESH_ARGS='-p ab --no-timestamps --no-index'
    export QUILT_DIFF_ARGS='--no-timestamps'

    mv "$srcdir"/debian .

    quilt push -av
  fi
}

build() {
  cd "${pkgname}-${_upstreamver}"
  ./configure --prefix=/usr --enable-transfig
  make FIG2DEV_LIBDIR=/usr/share/fig2dev XFIGLIBDIR=/usr/share/xfig
}

package() {
  cd "${pkgname}-${_upstreamver}"
  make DESTDIR="${pkgdir}" XFIGLIBDIR=/usr/share/xfig \
    FIG2DEV_LIBDIR=/usr/share/fig2dev MANPATH=/usr/share/man \
    install
  install -Dm644 ../LICENSE -t "${pkgdir}/usr/share/licenses/${pkgname}"
}