# Maintainer: Jesus E. <heckyel@riseup.net>
# Contriutor (Arch): Eric Belanger <eric@archlinux.org>

pkgname=fceux
pkgver=2.6.5
_debver=$pkgver
_debrel=2
pkgrel=1
pkgdesc="Fast and ultra-compatible NES/Famicom emulator"
url='https://github.com/TASEmulators/fceux'
arch=('i686' 'x86_64')
license=('GPL-2')
depends=('gd' 'lua51' 'minizip' 'qt-base' 'sdl2')
makedepends=('cmake' 'glu' 'mesa-libgl' 'ninja' 'setconf' 'scons' 'python-setuptools' 'quilt' 'ffmpeg')
optdepends=('ffmpeg: for recording')
source=("${pkgname}-${pkgver}.tar.xz::https://deb.debian.org/debian/pool/main/f/fceux/fceux_${pkgver}+dfsg1.orig.tar.xz"
        "https://deb.debian.org/debian/pool/main/f/fceux/fceux_${_debver}+dfsg1-${_debrel}.debian.tar.xz")
sha512sums=('710ecc734e0f940a04af35d441103928c3722cde27c309a3b6807d174b95fe60cea8f026fedcf8b7f45a01e72836775c695dde6e429684cbe23be9603c3be925'
            'c97b6b3426f9e9bf042876ff6ed1d4bd68b151097ab774934986c61c1ff0c33f553b02fd0f909efb0d094193dcac7ade2d10efc54ac41d45873fa10085efb96c')

prepare() {
  cd $pkgname-$pkgver

  if [[ ${pkgver%.*} = ${_debver%.*} ]]; then
    # Debian patches
    export QUILT_PATCHES=debian/patches
    export QUILT_REFRESH_ARGS='-p ab --no-timestamps --no-index'
    export QUILT_DIFF_ARGS='--no-timestamps'

    mv "$srcdir"/debian .

    # Doesn't apply
    rm -v debian/patches/install-fceux-to-usr-games.patch || true

    quilt push -av
  fi
}

build() {
  cmake -B build \
    -DCMAKE_C_FLAGS="$CFLAGS -fPIC -w" \
    -DCMAKE_CXX_FLAGS="$CXXFLAGS -fPIC -w" \
    -DCMAKE_INSTALL_PREFIX=/usr \
    -G Ninja \
    -S $pkgname-$pkgver
  ninja -C build
}

package() {
  DESTDIR="$pkgdir" ninja -C build install
  install -d "$pkgdir/usr/share/doc/$pkgname"
  cp -r $pkgname-$pkgver/documentation/* "$pkgdir/usr/share/doc/$pkgname/"
  install -Dm644 $pkgname-$pkgver/changelog.txt "$pkgdir/usr/share/doc/$pkgname/"
  install -Dm644 $pkgname-$pkgver/COPYING -t "$pkgdir/usr/share/licenses/$pkgname"
}