# Maintainer: Jesus E. <heckyel@riseup.net>

pkgname='f2fs-tools'
pkgver='1.14.0'
pkgrel='1'
pkgdesc='Tools for Flash-Friendly File System (F2FS)'
arch=('i686' 'x86_64')
url="https://git.kernel.org/pub/scm/linux/kernel/git/jaegeuk/${pkgname}.git"
url+='/about/'
depends=('util-linux')
license=('GPL-2')
# Jaegeuk Kim <jaegeuk@kernel.org>
validpgpkeys=('D3452A79D8C2B4EAC656F4224014A87E824850D2')
source=("${url/\/about\//}/snapshot/${pkgname}-${pkgver}.tar.gz")
sha512sums=('951b74178f99722550e73f331be066f124f6ee6022710f6b47ae47390b978b08f12a7f2a268d82ca69a32bf440cd3ce3adddc8a4c49c32df83da87e7f659f98d')

prepare() {
  autoreconf -fi "${srcdir}/${pkgname}-${pkgver}"
}

build() {
  mkdir "${srcdir}/build"
  cd "${srcdir}/build"
  "${srcdir}/${pkgname}-${pkgver}/configure" \
    --prefix='/usr' \
    --sbindir='/sbin'
  cd "${OLDPWD}"
  make -C "${srcdir}/build"
}

package() {
  make -C "${srcdir}/build" DESTDIR="${pkgdir}" 'install'

  # sg_write_buffer is provided in sg3_utils
  rm "${pkgdir}/sbin/sg_write_buffer"

  # license
  install -Dm '644' "${srcdir}/${pkgname}-${pkgver}/COPYING" -t \
    "${pkgdir}/usr/share/licenses/${pkgname}"
}