# Maintainer: Jesus E. <heckyel@riseup.net>

pkgname=entr
pkgver=4.7
_debver=$pkgver
_debrel=1
pkgrel=1
pkgdesc="Run arbitrary commands when files change"
license=('Simplified-BSD' 'ISC')
arch=('i686' 'x86_64')
url='https://eradman.com/entrproject/'
options=('strip')
depends=('glibc' 'libbsd')
makedepends=('quilt')
source=("https://eradman.com/entrproject/code/${pkgname}-${pkgver}.tar.gz"
        "http://deb.debian.org/debian/pool/main/e/entr/entr_${_debver}-${_debrel}.debian.tar.xz")
sha512sums=('2db61c9f66d3b8e138f23b8cb422cf56c71583a5116e614269c49fe7c336ac79cb77917b26b060f09142e2028fd96c3f169c11caffaae0e5d6e7c05bbb36d92c'
            '8523be6cf7b936ad6d7f68cf0a21a6c07abfe7645dd21ddd4e04ff9012b7e355ba60abc967c86585f7cebfd95319a18cf7706c697d15fccdd76650e19e86a4f1')

prepare() {
  cd "$pkgname-$pkgver"

  if [[ ${pkgver%.*} = ${_debver%.*} ]]; then
    # Debian patches
    export QUILT_PATCHES=debian/patches
    export QUILT_REFRESH_ARGS='-p ab --no-timestamps --no-index'
    export QUILT_DIFF_ARGS='--no-timestamps'

    mv "$srcdir"/debian .

    quilt push -av
  fi
}

build() {
  cd "$pkgname-$pkgver"
  cp Makefile.linux Makefile
  make PREFIX=/usr
}

package() {
  cd "$pkgname-$pkgver"
  make PREFIX=/usr DESTDIR="$pkgdir" install
  install -Dm644 LICENSE -t "${pkgdir}/usr/share/licenses/$pkgname"
}