# Maintainer: Jesus E. <heckyel@riseup.net>

pkgname=enscript
pkgver=1.6.5.90
_debver=1.6.5.90
_debrel=3
pkgrel=1
pkgdesc='Convert ASCII files to PostScript suitable for printing'
arch=('i686' 'x86_64')
url='https://git.savannah.gnu.org/cgit/enscript.git'
license=('GPL-3')
depends=('glibc' 'perl')
makedepends=('quilt')
backup=('etc/enscript/enscript.cfg')
source=(https://deb.debian.org/debian/pool/main/e/enscript/enscript_${pkgver}.orig.tar.gz
        https://deb.debian.org/debian/pool/main/e/enscript/enscript_${_debver}-${_debrel}.debian.tar.xz)
sha512sums=('54c51c2ef8d2c9e1eb3398e450ddeb31ddaea9870767d8c0d3bc936b11cd23e1b23301621e835e9694a603757e5aa0a84159cbd6afafd66fce7b3961c88e735f'
            '91dfffecc143fc492d32131a9e0deb4b761795a049e15477832eef043402a8f6d40f158f9b140f902923bf2dbc33645e2c49bb0ba2e282edfab740c22265c86d')

prepare() {
  cd $pkgname-$pkgver
  if [[ ${pkgver%.*} = ${_debver%.*} ]]; then
    # Debian patches
    export QUILT_PATCHES=debian/patches
    export QUILT_REFRESH_ARGS='-p ab --no-timestamps --no-index'
    export QUILT_DIFF_ARGS='--no-timestamps'

    mv "$srcdir"/debian .

    # Doesn't apply
    rm -v debian/patches/01_libpaper || true
    rm -v debian/patches/06_debian || true

    quilt push -av
  fi
}

build() {
  cd $pkgname-$pkgver
  ./configure --prefix=/usr --sysconfdir=/etc/enscript
  make
}

package() {
  cd $pkgname-$pkgver
  make DESTDIR="$pkgdir" install
  install -Dm644 COPYING -t "${pkgdir}/usr/share/licenses/$pkgname"
}