# Maintainer: Jesus E. <heckyel@riseup.net>

pkgname=enchant
pkgver=1.6.0
_pkgver=1-6-0
_debver=$pkgver
_debrel=11.1
pkgrel=3
pkgdesc="A wrapper library for generic spell checking"
arch=(i686 x86_64)
url='https://abiword.github.io/enchant/'
license=(LGPL-2.1)
depends=('aspell' 'glib2' 'hspell' 'hunspell' 'ispell' 'libvoikko')
makedepends=('quilt')
source=($pkgname-$pkgver.tar.gz::https://github.com/AbiWord/$pkgname/archive/refs/tags/$pkgname-$_pkgver.tar.gz
        https://deb.debian.org/debian/pool/main/e/$pkgname/${pkgname}_$_debver-$_debrel.debian.tar.xz)
sha512sums=('3de201553634d52e636ec3e36b13b5a1fba31091ce8e1a06e99b9e02ac478ae70da9e830f4334eedc36ff353ea6cda20d77d6d7899e1feb69cd04b96df915970'
            '90b36e5bc51449600e1074c6dc36e725776d291aab98a2c681baae145c6081a8f722ec749f9960577b634917dc8add239258739817d71c548534d908fbd3ccda')

prepare() {
  mv $pkgname-{$pkgname-$_pkgver,$pkgver}

  cd $pkgname-$pkgver
  if [[ ${pkgver%.*} = ${_debver%.*} ]]; then
    # Debian patches
    export QUILT_PATCHES=debian/patches
    export QUILT_REFRESH_ARGS='-p ab --no-timestamps --no-index'
    export QUILT_DIFF_ARGS='--no-timestamps'

    mv "$srcdir"/debian .

    quilt push -av
  fi

  autoreconf -vfi
}


build() {
  cd $pkgname-$pkgver
  ./configure \
    --prefix=/usr
  make
}

package() {
  cd $pkgname-$pkgver
  make DESTDIR="$pkgdir" install
  install -Dm644 COPYING.LIB -t $pkgdir/usr/share/licenses/$pkgname
}