# Maintainer: Jesus E. <heckyel@riseup.net>

pkgname=elinks
pkgver=0.13.2
_debver=$pkgver
_debrel=1
pkgrel=3
pkgdesc="An advanced and well-established feature-rich text mode web browser"
arch=('i686' 'x86_64')
url='http://elinks.or.cz'
license=('GPL-2')
depends=('bzip2' 'expat' 'gpm' 'libressl' 'lua51' 'libidn' 'gc' 'tre' 'zlib')
makedepends=('quilt')
source=("${pkgname}-${pkgver}.tgz::https://github.com/rkd77/elinks/archive/v${pkgver}.tar.gz"
        "https://deb.debian.org/debian/pool/main/e/elinks/elinks_${_debver}-${_debrel}.debian.tar.xz"
        "fix-build.patch")
sha512sums=('98d3dbd5621b8e43d3cbc98f0710772df38484830fb841d6b68b83508bc963ca8bc3cf2ecca6b1658e2c12ed498c8ef34e6f05f48814d249c2de2f5c80f7f07f'
            'f0c6f5a86e29351dc7681cff0b3c42948a4233f4806af4778333753934eb06099b8179e781ee4f7d6f34c1c2984f80f891d279b9e0420ace2f4bcb0a231711be'
            '995fc3b938f5ab291fcadbece295200d3f9e1a9b3305b356f26e44d5595fa00fbe9bba0cce8d98085558467658db18bf09278dcd5d8a1c609f225e943bf2dfba')

prepare() {
  cd $pkgname-$pkgver
  if [[ ${pkgver%.*} = ${_debver%.*} ]]; then
    # Debian patches
    export QUILT_PATCHES=debian/patches
    export QUILT_REFRESH_ARGS='-p ab --no-timestamps --no-index'
    export QUILT_DIFF_ARGS='--no-timestamps'

    mv "$srcdir"/debian .

    quilt push -av
  fi
}

build() {
  cd $pkgname-$pkgver
  sed -i 's/Terminal=1/Terminal=true/' "contrib/debian/$pkgname.desktop"
  [ -x configure ] || sh autogen.sh
  ./configure \
    --prefix=/usr \
    --mandir=/usr/share/man \
    --sysconfdir=/etc \
    --disable-smb \
    --without-x \
    --without-zstd \
    --enable-cgi \
    --enable-leds \
    --enable-256-colors \
    --enable-html-highlight \
    --enable-gopher \
    --with-zlib

  # additional fixes before building
  patch -Np1 -i ${srcdir}/fix-build.patch

  make
}

package() {
  cd $pkgname-$pkgver
  make DESTDIR="$pkgdir" install
  rm -f "$pkgdir/usr/share/locale/locale.alias"

  install -D -m644 "contrib/debian/$pkgname.desktop" \
    "$pkgdir/usr/share/applications/$pkgname.desktop"

  install -Dm644 COPYING -t "${pkgdir}/usr/share/licenses/${pkgname}"
}