# Maintainer: Jesus E. <heckyel@riseup.net>

pkgname=easytag
pkgver=2.4.3
_debver=$pkgver
_debrel=9
pkgrel=4
pkgdesc="Simple application for viewing and editing tags in audio files"
arch=('i686' 'x86_64')
url='https://wiki.gnome.org/Apps/EasyTAG'
license=('GPL-2')
depends=('cairo' 'gcc-libs' 'gdk-pixbuf2' 'glibc' 'id3lib' 'taglib' 'wavpack' 'zlib' 'opus' 'opusfile' 'libvorbis' 'speex')
makedepends=('atk' 'flac' 'glib2' 'gtk' 'harfbuzz' 'intltool' 'itstool' 'libid3tag' 'pango' 'python' 'yelp-tools' 'quilt')
source=("https://gitlab.gnome.org/GNOME/${pkgname}/-/archive/${pkgname}-${pkgver}/${pkgname}-${pkgname}-${pkgver}.tar.gz"
        "https://deb.debian.org/debian/pool/main/e/easytag/easytag_${_debver}-${_debrel}.debian.tar.xz"
        "remove-appstreamglib.patch")
sha512sums=('a14ce7432592e8430039f8960a9de70f49adf0a60bc4232e8d894b9cab09d72b8205dd1660a51718b655130a4cee69841106461df7d0b05b4b36b611398789e3'
            '3a6fe343279d0101963299a6f9e231f8b0f02784df650066a20e1968c95f7102fd731f6c70df7bc1a40327648a1ff2cd027df879c66170ea12eb05e2f72551ef'
            'a3ca13c93cd020b7174fc9becb8eecf8863b978b3a0585c0b06012355bc3bb5c12991a0779c7632397ec015d1e1e1b6c1f4941a6e31523c25c5d778323db9562')

prepare() {
  mv -v "${pkgname}-${pkgname}-${pkgver}" "${pkgname}-${pkgver}"
  cd "${pkgname}-${pkgver}"

  if [[ ${pkgver%.*} = ${_debver%.*} ]]; then
    # Debian patches
    export QUILT_PATCHES=debian/patches
    export QUILT_REFRESH_ARGS='-p ab --no-timestamps --no-index'
    export QUILT_DIFF_ARGS='--no-timestamps'

    mv "$srcdir"/debian .

    quilt push -av
  fi
  patch -Np1 -i ${srcdir}/remove-appstreamglib.patch

  ./autogen.sh
}

build() {
  cd "${pkgname}-${pkgver}"
  ./configure GLIB_COMPILE_SCHEMAS="/usr/bin/glib-compile-schemas" \
              --prefix=/usr \
              --disable-nautilus-actions
  make
}

package() {
  cd "${pkgname}-${pkgver}"
  make DESTDIR="${pkgdir}" install
  install -Dm644 COPYING -t "${pkgdir}/usr/share/licenses/$pkgname"
}