# Maintainer: Jesus E. <heckyel@riseup.net>

pkgname=dvdauthor
pkgver=0.7.2
_debver=0.7.2
_debrel=1
pkgrel=1
pkgdesc='DVD authoring tools'
arch=('i686' 'x86_64')
url='http://dvdauthor.sourceforge.net/'
license=('GPL-2')
depends=('libdvdread' 'graphicsmagick' 'libxml2')
makedepends=('quilt')
source=("https://downloads.sourceforge.net/$pkgname/$pkgname-$pkgver.tar.gz"
        "https://deb.debian.org/debian/pool/main/d/dvdauthor/dvdauthor_$_debver-$_debrel.debian.tar.xz"
        "support-graphicsmagick.patch")
sha512sums=('202b8bba38939d122dc864921a57e89906ca99ddabf44e3b07419cc42cc052567cd892b41f1171c9c195c9a770758e9319a942ea64d14ee8fa847588c7761125'
            'ef4296cc9786360620ebcb17633702143444aa797a04960ec9a766e421e6a9e362b4372538213fb927c18b74a73202bf043650338e0344c7a772703eab2288ca'
            'd554b563d1da551560fc49aaa9d8f005770bb493ed94b5795e4a37d142e7ff474757a99d4baaf9eb39d41bbbfd2d37a3e19cd8d19e5b6dd654f939732d162f01')

prepare() {
  cd $pkgname

  if [[ ${pkgver%.*} = ${_debver%.*} ]]; then
    # Debian patches
    export QUILT_PATCHES=debian/patches
    export QUILT_REFRESH_ARGS='-p ab --no-timestamps --no-index'
    export QUILT_DIFF_ARGS='--no-timestamps'

    mv "$srcdir"/debian .

    # Doesn't apply
    rm -v debian/patches/0001-add-config-rpath.patch || true

    quilt push -av
  fi

  # support for graphicsmagick
  patch -Np1 -i ../support-graphicsmagick.patch

  # don't search for obsolete freetype-config
  sed -e 's|freetype-config|pkg-config freetype2|' -i configure.ac

  autoreconf -vi
}

build() {
  cd $pkgname
  ./configure --prefix=/usr --with-graphicsmagick
  make
}

package() {
  cd $pkgname
  make DESTDIR="$pkgdir" install
  install -Dm644 COPYING -t "${pkgdir}/usr/share/licenses/$pkgname"
}