# Maintainer: Jesus E. <heckyel@riseup.net>

pkgname=dsniff
pkgver=2.4b1
_debver=$pkgver
_debrel=30
pkgrel=2
pkgdesc="Free and libre collection of tools for network auditing and penetration testing"
url='https://www.monkey.org/~dugsong/dsniff/'
arch=('i686' 'x86_64')
license=('Modified-BSD')
depends=('glibc' 'libpcap' 'libressl' 'libxmu' 'glib2' 'libnet' 'libnids' 'libtirpc')
makedepends=('rpcsvc-proto' 'quilt')
options=('!makeflags')
source=("https://www.monkey.org/~dugsong/${pkgname}/beta/${pkgname}-${pkgver}.tar.gz"
        "https://deb.debian.org/debian/pool/main/d/dsniff/dsniff_${_debver}+debian-${_debrel}.debian.tar.xz")
sha512sums=('62dafab293de6dc3e9b01561b3627d63ca334467c01c3550a6318d8bcbe99d5a301ec16967af34065a14e8bca1c4b6a41da766cbd51ebd8338615b950c4f642f'
            '45ffe34fcd30cd1461a354891b9d5567038cc176dbfa79c67020075cd40ae09b7092954925019e583d0d69cae76a558049b489745454a8034ce3e9e832c58f64')

prepare() {
  cd "${pkgname}-2.4"
  if [[ ${pkgver%.*} = ${_debver%.*} ]]; then
    # Debian patches
    export QUILT_PATCHES=debian/patches
    export QUILT_REFRESH_ARGS='-p ab --no-timestamps --no-index'
    export QUILT_DIFF_ARGS='--no-timestamps'

    mv "$srcdir"/debian .

    quilt push -av
  fi
  autoreconf -fiv
}

build() {
  cd ${pkgname}-2.4
  ./configure \
    --with-libtirpc \
    --prefix=/usr
  make
}

package() {
  cd ${pkgname}-2.4
  make install_prefix="${pkgdir}" install
  install -Dm 644 LICENSE -t "${pkgdir}/usr/share/licenses/${pkgname}"
  install -Dm 644 CHANGES README -t "${pkgdir}/usr/share/doc/${pkgname}"
}