# Maintainer: Jesus E. <heckyel@riseup.net>

pkgname=dosbox
pkgver=0.74.3
_realpkgver=0.74-3
_debver=0.74-3
_debrel=3
pkgrel=3
pkgdesc="Emulator with builtin DOS for running DOS Games"
arch=('i686' 'x86_64')
url='https://dosbox.sourceforge.net/'
license=('GPL-2' 'Modified-BSD')
depends=('sdl_net' 'zlib' 'sdl_sound' 'libpng' 'alsa-lib' 'gcc-libs' 'glu')
makedepends=('quilt')
source=("https://downloads.sourceforge.net/$pkgname/$pkgname-$_realpkgver.tar.gz"
        "https://deb.debian.org/debian/pool/main/d/dosbox/dosbox_$_debver-$_debrel.debian.tar.xz")
sha512sums=('3770f1578e71730168fba01809585f2a05cf8c4d420524687ba28791d242faad294401bb9cd268bba725798e1db853551f274dc00a4024331f5dcef9f87f8f5f'
            '7817c042a85c09a903bebcfb7be5ef76c1ad197e9032340484722091e0d298509cd6c4edd8cd6df8bd5dde24d7e39df4e2a58809ddbb82b6f9f67a29f29fe5c0')

prepare() {
  cd "${srcdir}/$pkgname-$_realpkgver"
  if [[ ${_realpkgver%.*} = ${_debver%.*} ]]; then
    # Debian patches
    export QUILT_PATCHES=debian/patches
    export QUILT_REFRESH_ARGS='-p ab --no-timestamps --no-index'
    export QUILT_DIFF_ARGS='--no-timestamps'

    mv "$srcdir"/debian .

    quilt push -av
  fi
  autoreconf -vfi
}

build() {
  cd "${srcdir}/$pkgname-$_realpkgver"
  ./configure \
    --prefix=/usr \
    --sysconfdir=/etc/dosbox
  make
}

package() {
  cd "${srcdir}/$pkgname-$_realpkgver"
  make DESTDIR="${pkgdir}" install

  # install docs, make does not install them
  install -Dm644 README "${pkgdir}"/usr/share/doc/$pkgname/README
  install -Dm644 docs/README.video "${pkgdir}"/usr/share/doc/$pkgname/README.video

  # install icon and desktop-file
  install -Dm644 "debian/icons/hicolor/48x48/apps/$pkgname.png" -t "${pkgdir}/usr/share/pixmaps"
  install -Dm644 "debian/$pkgname.desktop" -t "${pkgdir}/usr/share/applications"

  # license
  install -Dm644 COPYING debian/copyright -t "${pkgdir}/usr/share/licenses/$pkgname"
}