# Maintainer: Jesus E. <heckyel@riseup.net>

pkgname=docbook2x
pkgver=0.8.8
_debver=0.8.8
_debrel=17
pkgrel=1
pkgdesc="A software package that converts DocBook documents into the traditional Unix man page format and the GNU Texinfo format."
arch=('i686' 'x86_64')
url='http://docbook2x.sourceforge.net'
license=('Expat')
depends=('glibc' 'perl-sgmls' 'perl-xml-parser' 'perl-xml-sax' 'libxslt'
	 'openjade' 'perl-xml-sax-expat')
makedepends=('texinfo' 'quilt')
source=(https://downloads.sourceforge.net/$pkgname/docbook2X-$pkgver.tar.gz
        https://deb.debian.org/debian/pool/main/d/docbook2x/docbook2x_$_debver-$_debrel.debian.tar.xz)
sha512sums=('cc336017ad734fc62d96d289105e8ea154c418a03a37f3e21b0b3520063f8b466b4aae5a5aec2e0b83f6324c6c79b5557247a93338d0a9882a94a44112f6b65c'
            '85ee99f753cb6494830726b88f9379b2a50fccc034204ed06c4ac6295cdf3e8654e39286347033f207714e060f4d27d6f705a01611270896b7da22563cc082aa')

prepare() {
  cd "$srcdir"/docbook2X-$pkgver

  if [[ ${pkgver%.*} = ${_debver%.*} ]]; then
    # Debian patches
    export QUILT_PATCHES=debian/patches
    export QUILT_REFRESH_ARGS='-p ab --no-timestamps --no-index'
    export QUILT_DIFF_ARGS='--no-timestamps'

    mv "$srcdir"/debian .

    quilt push -av
  fi

  sed -e 's/AM_CONFIG_HEADER(/AC_CONFIG_HEADERS(/' -i configure.ac
  autoreconf -vfi
}

build()  {
  cd docbook2X-$pkgver
  # to avoid file conflicts with docbook2* from docbook-utils
  ./configure \
    --prefix=/usr \
    --mandir=/usr/share/man \
    --program-transform-name 's,docbook2,db2x_docbook2,'
  make
}

package() {
  cd docbook2X-$pkgver
  make DESTDIR="$pkgdir" install
  install -D -m0644 COPYING -t "$pkgdir"/usr/share/licenses/$pkgname
  sed -i 's|http://docbook2x.sf.net/latest|/usr/share/docbook2X|g' \
    "$pkgdir"/usr/bin/db2x_xsltproc
}