# Maintainer: Jesus E. <heckyel@riseup.net>

pkgname=dmg2img
pkgver=1.6.7
_debver=$pkgver
_debrel=1
pkgrel=1
pkgdesc="A free and libre CLI tool to uncompress DMG-files to the HFS+ IMG format"
arch=('i686' 'x86_64')
url='https://vu1tur.eu.org/tools/'
license=('GPL-2')
depends=('libressl' 'bzip2')
makedepends=('quilt')
source=("https://vu1tur.eu.org/tools/$pkgname-$pkgver.tar.gz"
        "https://deb.debian.org/debian/pool/main/d/dmg2img/dmg2img_$_debver-$_debrel.debian.tar.xz")
sha512sums=('4c42841c5cdbf868b6038648a6c83e78d4b7f2010f7065d7b3f4c2c04d13af9489716c1dfa867aff5f3c3b3eef96dc3fc0610eff13fec139265f37f468e339e6'
            '2df07abf79a3702789e8eeb7e76487cbc71ebdfed91b86cf7fa8e78c934b909bbd6847738922b58d132be490f388f1bf7939cb56e57056083f11b5a703df02ff')

prepare() {
  cd "$srcdir/$pkgname-$pkgver"
  if [[ ${pkgver%.*} = ${_debver%.*} ]]; then
    # Debian patches
    export QUILT_PATCHES=debian/patches
    export QUILT_REFRESH_ARGS='-p ab --no-timestamps --no-index'
    export QUILT_DIFF_ARGS='--no-timestamps'

    mv "$srcdir"/debian .

    quilt push -av
  fi
}

build() {
  cd "$srcdir/$pkgname-$pkgver"
  make PREFIX="/usr"
}

package() {
  cd "$srcdir/$pkgname-$pkgver"
  make PREFIX="/usr" DESTDIR="$pkgdir" install
  install -Dm644 COPYING -t "${pkgdir}/usr/share/licenses/${pkgname}/"
}