# Maintainer: Jesus E. <heckyel@riseup.net>

pkgname=djvulibre
pkgver=3.5.28
_debver=3.5.28
_debrel=2
pkgrel=1
pkgdesc='Suite to create, manipulate and view DjVu (déjà vu) documents'
url='http://djvu.sourceforge.net/'
arch=('i686' 'x86_64')
license=('GPL-2')
makedepends=('librsvg-legacy' 'quilt')
depends=('libtiff' 'hicolor-icon-theme')
source=(https://downloads.sourceforge.net/project/djvu/DjVuLibre/$pkgver/djvulibre-$pkgver.tar.gz
        https://deb.debian.org/debian/pool/main/d/djvulibre/djvulibre_$_debver-$_debrel.debian.tar.xz)
sha512sums=('db3b8a5b56d700e911be32057f721a2a597e6f52e6fade203ad75ad76ab2d8facff2e474fd18beea703ccd5fa6425352e619a8fda40e69add1724dbee26050c6'
            'cfe00fea2dd46ba9f19afd62821a3823b725deda33afc039fd2d51d7d9eeaac2c4277419404101d11f725d735c918e969954d8e3155d70811c567fd6c55db38b')

prepare() {
  cd ${pkgname}-${pkgver}
  if [[ ${pkgver%.*} = ${_debver%.*} ]]; then
    # Debian patches
    export QUILT_PATCHES=debian/patches
    export QUILT_REFRESH_ARGS='-p ab --no-timestamps --no-index'
    export QUILT_DIFF_ARGS='--no-timestamps'

    mv "$srcdir"/debian/patches ./debian/
    rm -rf "$srcdir"/debian

    quilt push -av
  fi
}

build() {
  cd ${pkgname}-${pkgver}
  ./configure --prefix=/usr --disable-desktopfiles
  make
}

package() {
  cd ${pkgname}-${pkgver}
  make DESTDIR="${pkgdir}" install
  for sz in 22 32 48 64; do
    install -Dm644 desktopfiles/prebuilt-hi${sz}-djvu.png "${pkgdir}/usr/share/icons/hicolor/${sz}x${sz}/mimetypes/image-vnd.djvu.mime.png"
  done
  install -Dm644 COPYING -t "${pkgdir}/usr/share/licenses/$pkgname"
}