# Maintainer: Jesus E. <heckyel@riseup.net>

pkgname=dia
pkgver=0.97.3
pkgrel=1
pkgdesc="A free and libre GTK+ based diagram creation program"
arch=('i686' 'x86_64')
license=('GPL-2')
url='http://live.gnome.org/Dia'
depends=('libxslt' 'gtk2')
makedepends=('intltool' 'docbook-xsl' 'gettext-tiny')
options=('docs' '!emptydirs')
source=("https://ftp.gnome.org/pub/gnome/sources/${pkgname}/0.97/${pkgname}-${pkgver}.tar.xz"
        "dia-0.9.3-cve-2019-19451.patch")
sha512sums=('34298980be930b87cb4a636344e4cb2a7e43eedc00b0969a5e446cee9b74b616fdc8c798efcb9a5832b98741f2e20632a44037b2bcb436f59591d531ef441efa'
            '13812395b220789b404c68f688aeb7ec82336d84751a93c5a9a73b32d02ba4b89b64420ce264e3e1b7efd4ecedadfbc2f78997b12cf2320dfa56ebfb20fa5edc')

prepare() {
  cd "${pkgname}-${pkgver}"
  sed -i 's#freetype-config --cflags#pkg-config --cflags freetype2#' configure
  sed -i 's#freetype-config --libs#pkg-config --libs freetype2#' configure
  patch -Np1 -i "${srcdir}/dia-0.9.3-cve-2019-19451.patch"
}

build() {
  cd "${pkgname}-${pkgver}"

  ./configure --prefix=/usr \
    --with-cairo \
    --disable-python \
    --disable-gnome \
    --with-hardbooks
  sed -i 's#SUBDIRS = lib objects plug-ins shapes app bindings samples po sheets data doc tests installer#SUBDIRS = lib objects plug-ins shapes app bindings samples po sheets data tests installer#' Makefile
  make
  cd doc
  make html
}

package() {
  cd "${pkgname}-${pkgver}"
  make DESTDIR="${pkgdir}" install
  install -Dm644 COPYING -t "${pkgdir}/usr/share/licenses/$pkgname"
  cd doc
  make DESTDIR="${pkgdir}" install-html
  ln -sf ../doc/$pkgname/html "${pkgdir}/usr/share/$pkgname/help"
}