# Maintainer: Jesus E. <heckyel@riseup.net>

pkgname=deutex
pkgver=5.2.2
pkgrel=1
pkgdesc='Composer and decomposer for WAD files'
arch=('i686' 'x86_64')
url='https://github.com/Doom-Utils/deutex'
license=('GPL-2')
depends=('libpng')
makedepends=('asciidoc')
source=(https://github.com/Doom-Utils/deutex/releases/download/v${pkgver}/${pkgname}-${pkgver}.tar.zst
        update-copyright-year.patch)
sha512sums=('5f3c3d3ecad3a7949270a10c3c7e3a8be938389d4846dcac171526a9fd0485e056889323d303f61630e8735e5735edc91df7ad4efaba3d0b2b66a9d719017ebc'
            'b8a636af9e9628f27298c189491f891ad7ffb8dd8c14b68fb0953e0fb1edc96539a2d489d15c696b8f5b5bf953980e4dab68e9272c56bdf3e414bcbc0fcba16f')

prepare() {
  cd "$pkgname-$pkgver"

  for patch in ../*.patch; do
    if [ ! -f "$patch" ]; then
      break;
    else
      patch -p1 -i "$patch"
    fi
  done
}

build() {
  cd "$pkgname-$pkgver"

  ./configure --prefix=/usr
  make
}

package() {
  cd "$pkgname-$pkgver"

  make DESTDIR="$pkgdir" install
  install -Dm644 COPYING -t "${pkgdir}/usr/share/licenses/$pkgname"
}