# Maintainer: Jesus E. <heckyel@riseup.net>

pkgname=cwm
pkgver=7.1
_debver=$pkgver
_debrel=1
pkgrel=1
pkgdesc="OpenBSD fork of calmwm, a clean and lightweight window manager"
arch=('i686' 'x86_64')
url='https://github.com/leahneukirchen/cwm'
license=('ISC' 'Modified-BSD')
depends=('libxft' 'libxrandr')
optdepends=('slock: for the default screen locker'
            'st: for the default terminal emulator')
makedepends=('quilt')
source=("${pkgname}-${pkgver}.tar.gz::https://github.com/leahneukirchen/cwm/archive/refs/tags/v${pkgver}.tar.gz"
        "https://deb.debian.org/debian/pool/main/c/cwm/cwm_${_debver}-${_debrel}.debian.tar.xz"
        "cwm.desktop"
        "change-default-binaries.patch")
sha512sums=('aa14bc7a43a522f4b83d3f9a3b8a8344c339b52aac4733f410e388df56a2dc4e86ee1ae9f05b53ff3139808f87f38a4b2da57bf0525482613d46651e8f08c718'
            'ffa0070cc58668c3025a6c2fc69aa6af79b89a885bb86922a0bb58421dfb3295fa9c3687fe34d12f0e8cb2f2857aaae45be9fad173ef9840b44ab8d5cc253413'
            '9ac67d2954e75fd282e2e73db187a8a33d68fa858fec1b07ed19a57de864c90b0fc976b41583e662d3af3771f3bed428441283037b7403a086805cf9a3c0a097'
            '59870a1fbaa5cb41faa730642bbbdac4f0bc17023a64420550e335567e743dbcd18fb6489df508d9e3b7625db0cbe9c4165951a79e81caad4991724c504d4a36')

prepare() {
  cd $pkgname-$pkgver

  if [[ ${pkgver%.*} = ${_debver%.*} ]]; then
    # Debian patches
    export QUILT_PATCHES=debian/patches
    export QUILT_REFRESH_ARGS='-p ab --no-timestamps --no-index'
    export QUILT_DIFF_ARGS='--no-timestamps'

    mv "$srcdir"/debian .

    # Doesn't apply
    rm -v debian/patches/change-default-binaries || true

    quilt push -av
  fi
  patch -p1 -i "${srcdir}/change-default-binaries.patch"
}

build() {
  cd $pkgname-$pkgver
  make
}

package() {
  cd $pkgname-$pkgver
  make DESTDIR="$pkgdir" PREFIX=/usr install
  install -Dm644 ${srcdir}/cwm.desktop -t $pkgdir/usr/share/xsessions
  install -Dm644 debian/copyright -t $pkgdir/usr/share/licenses/$pkgname
}