# Maintainer: Jesus E. <heckyel@riseup.net>

pkgname=cups-filters
pkgver=1.28.17
_debver=$pkgver
_debrel=3
pkgrel=2
pkgdesc="OpenPrinting CUPS Filters"
arch=('i686' 'x86_64')
url='https://wiki.linuxfoundation.org/openprinting/cups-filters'
license=('GPL-2')
depends=('lcms2' 'poppler' 'qpdf' 'graphicsmagick' 'liblouis' 'ijs' 'libcups' 'libexif')
makedepends=('ghostscript' 'ttf-dejavu' 'python' 'mupdf-tools' 'quilt')
optdepends=('ghostscript: for non-PostScript printers to print with CUPS to convert PostScript to raster images'
	    'foomatic-db: drivers use Ghostscript to convert PostScript to a printable form directly'
	    'foomatic-db-engine: drivers use Ghostscript to convert PostScript to a printable form directly'
	    'antiword: needed to convert documents (requires also docx2txt)')
backup=(etc/cups/cups-browsed.conf)
source=("${pkgname}-${pkgver}.tar.gz::https://deb.debian.org/debian/pool/main/c/cups-filters/cups-filters_${pkgver}.orig.tar.gz"
        "https://security.debian.org/debian-security/pool/updates/main/c/cups-filters/cups-filters_${_debver}-${_debrel}+deb12u1.debian.tar.xz"
        "cups-browsed.initd"
        "cups-browsed.run")
provides=('foomatic-filters')
replaces=('foomatic-filters')
conflicts=('foomatic-filters')
sha512sums=('dd22a8e29330ecbef64772c311c1d7c48a48a9037687da8059d73d26c54740065d4416ccb6776203762d1e0625af143d4c156cf352fb9962d1ae89aa27e87d27'
            '3df9b3f6ef86ffc44a7e8cb178a3c42df393bfa4b244744564c624116f02360540c44bb25c878feb957b1a5fe349cf7b3e4d5b0ad5ea3c2bf17806d584ff05ea'
            'd2d47ded65886e69d1b8bb910401898d5d1ef442bb119c2f2d2f798d20a3064d3e8a68d4a14544d94dd67b7af6f62a4725d50b680cd1d3ecfcb20ea5d6b2d026'
            '3c6c959d06870a4665add767797ccf4a78ebab8a139686655ee22eb82b3762ed19f2b55b7646bc837be85f681682b941725fda21b82dff66fc64fa17a8206da0')

prepare() {
  cd $pkgname-$pkgver
  if [[ ${pkgver%.*} = ${_debver%.*} ]]; then
    # Debian patches
    export QUILT_PATCHES=debian/patches
    export QUILT_REFRESH_ARGS='-p ab --no-timestamps --no-index'
    export QUILT_DIFF_ARGS='--no-timestamps'

    mv "$srcdir"/debian .

    quilt push -av
  fi
  autoreconf -vfi
}

build() {
  cd $pkgname-$pkgver
  ./configure --prefix=/usr  \
    --sysconfdir=/etc \
    --localstatedir=/var \
    --with-rcdir=no \
    --disable-avahi \
    --with-browseremoteprotocols=DNSSD,CUPS \
    --enable-auto-setup-driverless \
    --with-test-font-path=/usr/share/fonts/TTF/DejaVuSans.ttf \
    --disable-dbus
  make
}

package() {
  cd $pkgname-$pkgver
  make DESTDIR="$pkgdir/" install

  # OpenRC
  install -Dm755 $srcdir/cups-browsed.initd $pkgdir/etc/init.d/cups-browsed

  # runit
  install -Dm755 $srcdir/cups-browsed.run $pkgdir/etc/sv/cups-browsed/run

  # use lp group from cups
  chgrp -R lp ${pkgdir}/etc/cups

  # license
  install -Dm644 "${srcdir}"/${pkgname}-${pkgver}/COPYING "${pkgdir}"/usr/share/licenses/${pkgname}/COPYING
}