# Maintainer: Jesus E. <heckyel@riseup.net>

pkgname=cscope
pkgver=15.9
_debver=$pkgver
_debrel=1
pkgrel=1
pkgdesc="A developers tool for browsing program code"
arch=('i686' 'x86_64')
url='https://cscope.sourceforge.net/'
license=('Modified-BSD')
depends=('ncurses' 'sh')
makedepends=('quilt')
options=('!emptydirs')
source=("https://sourceforge.net/projects/cscope/files/cscope/v${pkgver}/${pkgname}-${pkgver}.tar.gz"
        "https://deb.debian.org/debian/pool/main/c/cscope/cscope_${_debver}-${_debrel}.debian.tar.xz")
sha512sums=('f3b95da5eb5c036cd39215785990c7cce7ce7b8eda4b18e60792e70d01ffb63809ce32ace310a9aefd88e6761c1609039ccfab0e8e49f81730bc1630babbcb80'
            'de4a6620b2aeb0e513a0da622ab232c6aca1e9cd96405371c5b9eb462a2087e4a5c5c8e941068fde039cab6cf98bda3efee7efdc7e8efe0c34172e50c7d1a90a')

prepare() {
  cd "${srcdir}/${pkgname}-${pkgver}"
  if [[ ${pkgver%.*} = ${_debver%.*} ]]; then
    # Debian patches
    export QUILT_PATCHES=debian/patches
    export QUILT_REFRESH_ARGS='-p ab --no-timestamps --no-index'
    export QUILT_DIFF_ARGS='--no-timestamps'

    mv "$srcdir"/debian .

    quilt push -av
  fi
}

build() {
  cd "${srcdir}/${pkgname}-${pkgver}"
  sed -i 's|/usr/local/lib/cs|/usr/lib/cs|' contrib/ocs

  ./configure \
    --prefix=/usr
  make
}

package() {
  cd "${srcdir}/${pkgname}-${pkgver}"
  make DESTDIR="${pkgdir}" install

  install -Dm644 COPYING -t "${pkgdir}"/usr/share/licenses/$pkgname

  cd contrib/xcscope
  install -Dm644 xcscope.el "${pkgdir}"/usr/share/emacs/site-lisp/xcscope.el
  install -m755 cscope-indexer "${pkgdir}"/usr/bin
}