# Maintainer: Jesus E. <heckyel@riseup.net>

pkgname=crispy-doom
pkgdesc="Vanilla-compatible enhanced 3D game-engine"
pkgver=7.0
pkgrel=1
arch=('i686' 'x86_64')
url='https://github.com/fabiangreffrath/crispy-doom'
license=('GPL-2')
depends=('hicolor-icon-theme' 'libpng' 'libsamplerate' 'sdl2_mixer' 'sdl2_net')
makedepends=('python')
optdepends=('freedm: Free and libre deathmatch game'
            'freedoom: Free and libre action-games'
            'blasphemer: Free and libre dark-fantasy game')
groups=('games')
install=$pkgname.install
source=("https://github.com/fabiangreffrath/crispy-doom/archive/refs/tags/${pkgname}-${pkgver}.tar.gz")
sha512sums=('d2e182f8a81b164d09ff0ed2bb7f507349f9edf55b3d1a62b54a0cc76dd3b407722704dd3e58d5736018807c8c39147401972e05f0d6ebb8606d016e2b68b37f')

prepare() {
  mv "$pkgname-$pkgname-$pkgver" "$pkgname-$pkgver"
  cd $pkgname-$pkgver
  ./autogen.sh \
    --prefix=/usr \
    --bindir=/usr/games
}

build() {
  cd $pkgname-$pkgver
  make
}

package() {
  cd $pkgname-$pkgver
  make DESTDIR="$pkgdir" install

  # remove data creating problems with other packages
  rm -rf "$pkgdir"/usr/share/man/man5/default.cfg.5 \
         "$pkgdir"/usr/share/man/man5/heretic.cfg.5 \
         "$pkgdir"/usr/share/man/man5/hexen.cfg.5 \
         "$pkgdir"/usr/share/man/man6/chocolate-{server,setup}.6

  # remove non-free data
  rm "${pkgdir}"/usr/games/crispy-{strife,strife-setup,hexen,hexen-setup}
  rm "${pkgdir}"/usr/share/applications/io.github.fabiangreffrath.{Hexen,Strife}.desktop
  rm -rf "${pkgdir}"/usr/share/applications/screensavers
  rm "${pkgdir}"/usr/share/bash-completion/completions/crispy-{hexen,strife}
  rm -rf "${pkgdir}"/usr/share/doc/crispy-{hexen,strife}
  rm "${pkgdir}"/usr/share/icons/hicolor/128x128/apps/crispy-{hexen,strife}.png
  rm "${pkgdir}"/usr/share/man/man5/crispy-{hexen,strife}.cfg.5
  rm "${pkgdir}"/usr/share/man/man6/crispy-{hexen,hexen-setup,strife,strife-setup}.6
  rm "${pkgdir}"/usr/share/metainfo/io.github.fabiangreffrath.{Hexen,Strife}.metainfo.xml

  # install license
  install -Dm644 COPYING.md -t "${pkgdir}/usr/share/licenses/$pkgname"
}