# Maintainer: Jesus E. <heckyel@riseup.net>

pkgname=confuse
pkgver=3.3
_debver=3.3
_debrel=2
pkgrel=1
pkgdesc='C-library for parsing configuration files'
arch=('i686' 'x86_64')
url='https://github.com/libconfuse/libconfuse'
license=('ISC')
depends=('glibc')
makedepends=('quilt')
source=(https://github.com/libconfuse/libconfuse/releases/download/v${pkgver}/${pkgname}-${pkgver}.tar.gz
        https://deb.debian.org/debian/pool/main/libc/libconfuse/libconfuse_$_debver-$_debrel.debian.tar.xz)
options=('!emptydirs')
sha512sums=('07f994ca670778ea3dd667b96e1109a90f1f886184b124a9249b60c724d35e423600ed33b46d46ef9299b8b531784e8023af6fad4c88b72791c86c0b1b7c370e'
            'b1bce2a1c6230e2583bfca23f927ae64b7118df6e9c8d7bddd000fb78bca30dc64ff480e2af4b8c6bd9d19df299a28cb314b11ebf1b8d4f35e4c5f3c87831765')

prepare() {
  cd $pkgname-$pkgver

  if [[ ${pkgver%.*} = ${_debver%.*} ]]; then
    # Debian patches
    export QUILT_PATCHES=debian/patches
    export QUILT_REFRESH_ARGS='-p ab --no-timestamps --no-index'
    export QUILT_DIFF_ARGS='--no-timestamps'

    mv "$srcdir"/debian .

    # Doesn't apply and seems unimportant
    rm -v debian/patches/de.po.patch || true

    quilt push -av
  fi
}

build() {
  cd ${pkgname}-${pkgver}
  ./configure --prefix=/usr --enable-shared
  make
}

check() {
  cd ${pkgname}-${pkgver}
  make check
}

package() {
  cd ${pkgname}-${pkgver}
  make DESTDIR="${pkgdir}" install
  install -D -m 644 -t "${pkgdir}/usr/share/licenses/${pkgname}/" LICENSE
}