# Maintainer: Jesus E. <heckyel@riseup.net>

pkgname=cmatrix
pkgver=2.0
_debver=2.0
_debrel=3
pkgrel=1
pkgdesc="A curses-based scrolling 'Matrix'-like screen"
arch=('i686' 'x86_64')
url='https://www.asty.org/cmatrix/'
license=('GPL-3')
depends=('ncurses')
makedepends=('cmake' 'quilt')
optdepends=('kbd: cmatrix-tty custom font'
            'xterm: cmatrix-tty custom font')
source=("cmatrix-$pkgver.tgz::https://github.com/abishekvashok/cmatrix/archive/v$pkgver.tar.gz"
        "https://deb.debian.org/debian/pool/main/c/cmatrix/cmatrix_${_debver}-${_debrel}.debian.tar.xz"
        "cmatrix-tty")
sha512sums=('1aeecd8e8abb6f87fc54f88a8c25478f69d42d450af782e73c0fca7f051669a415c0505ca61c904f960b46bbddf98cfb3dd1f9b18917b0b39e95d8c899889530'
            'a9366f88ec9db692bf6ab6dca5f78d46b463f7656e5402a5b997715750d0d3c852148420e9fb8394e71deba4787ff3125c1cc1c9d84f7e5ec4267d4777852733'
            'f51de7e7b849e4c99ed2b1cd66173a469f3fa957435dee96a9f234baf0ce09ed75ca095716c10e4625aa8e76e88d10aa4e62d02691a3bdedc4f3bcd378e09f8b')

prepare() {
  mkdir build

  cd ${pkgname}-${pkgver}
  if [[ ${pkgver%.*} = ${_debver%.*} ]]; then
    # Debian patches
    export QUILT_PATCHES=debian/patches
    export QUILT_REFRESH_ARGS='-p ab --no-timestamps --no-index'
    export QUILT_DIFF_ARGS='--no-timestamps'

    mv "$srcdir"/debian .

    quilt push -av
  fi
}

build() {
  cd build
  cmake ../$pkgname-$pkgver \
    -D CMAKE_BUILD_TYPE=Release \
    -D CMAKE_INSTALL_PREFIX=/usr \
    #-D CONSOLE_FONTS_DIRS=/usr/share/kbd/consolefonts \
    #-D X_FONTS_DIRS=/usr/share/fonts/misc \
    #-D UNIX=true
  make
}

package() {
  # only the binary has a target to install
  make -C build DESTDIR="$pkgdir" install

  cd $pkgname-$pkgver

  # install X font
  install -D -m644 mtx.pcf "$pkgdir"/usr/share/fonts/misc/mtx.pcf

  # install console font
  install -D -m644 matrix.fnt "$pkgdir"/usr/share/kbd/consolefonts/matrix.fnt
  install -D -m644 matrix.psf.gz "$pkgdir"/usr/share/kbd/consolefonts/matrix.psf.gz

  # todo: fix the pretty wrapper
  #install -Dm755 "$srcdir/cmatrix-tty" "$pkgdir/usr/bin/cmatrix-tty"

  for i in AUTHORS NEWS COPYING README ChangeLog INSTALL; do
    install -Dm644 $i "$pkgdir/usr/share/doc/$pkgname/$i"
  done

  install -Dm644 cmatrix.1 "$pkgdir/usr/share/man/man1/cmatrix.1"
  install -Dm644 COPYING -t "${pkgdir}/usr/share/licenses/$pkgname"
}