# Maintainer: Jesus E. <heckyel@riseup.net>

pkgname=cmark
pkgver=0.29.0
_debver=0.29.0
_debrel=4
pkgrel=1
pkgdesc='CommonMark parsing and rendering library and program in C'
arch=('i686' 'x86_64')
url='https://github.com/jgm/cmark'
license=('Simplified-BSD')
depends=('glibc')
makedepends=('cmake' 'python' 'quilt')
source=("$pkgname-$pkgver.tar.gz::https://github.com/jgm/cmark/archive/$pkgver.tar.gz"
        "https://deb.debian.org/debian/pool/main/c/cmark/cmark_$_debver-$_debrel.debian.tar.xz")
sha512sums=('06eb110cfd90c9e980c022b7588e28864d15a4da5d07d61ad4b27c6de47367492b9e58e9434e62b07517aa6dc484f17af13916808be3188f38c37d20cbf33112'
            '3447e3dabcc85ab5a343ac352b0b8d39a313525964a325fbc04d9d28f02485b7283a060614af42df5c97f8077bb1132559a500ca9f8afcfd1ccc25caa6ec0c6c')

prepare() {
  mkdir -p build

  cd ${srcdir}/${pkgname}-${pkgver}
  if [[ ${pkgver%.*} = ${_debver%.*} ]]; then
    # Debian patches
    export QUILT_PATCHES=debian/patches
    export QUILT_REFRESH_ARGS='-p ab --no-timestamps --no-index'
    export QUILT_DIFF_ARGS='--no-timestamps'

    mv "$srcdir"/debian .

    quilt push -av
  fi
}

build() {
  cd build
  cmake -DCMAKE_INSTALL_PREFIX=/usr -DCMAKE_INSTALL_LIBDIR=/usr/lib ../cmark-$pkgver
  make
}

check() {
  cd build
  make test
}

package() {
  cd build
  make install DESTDIR="$pkgdir"
  install -Dm644 "$srcdir"/cmark-$pkgver/COPYING -t "$pkgdir"/usr/share/licenses/$pkgname
}