# Maintainer: Jesus E. <heckyel@riseup.net>

pkgname=claws-mail
pkgver=4.1.1
_debver=$pkgver
_debrel=2
pkgrel=2
pkgdesc="A GTK based e-mail client"
arch=('i686' 'x86_64')
license=('GPL-3')
conflicts=('claws-mail')
provides=('claws-mail')
url='https://www.claws-mail.org'
depends=('gtk' 'gnutls' 'startup-notification' 'enchant' 'gpgme'
         'libetpan' 'compface' 'libsm')
makedepends=('poppler-glib' 'libytnef' 'libical'
             'bogofilter' 'valgrind' 'dillo' 'python' 'gumbo-parser' 'quilt')
optdepends=('perl: needed for perl plugin'
            'bogofilter: adds support for spamfiltering'
            'libxml2: for rssyl plugins'
            'curl: for vcalendar, rssyl and spamreport plugins'
            'libarchive: for archive plugin and various other plugins'
            'libytnef: for tnef_parse plugin'
            'poppler-glib: for pdf viewer plugin'
            'ghostscript: for pdf viewer plugin'
            'libical: for vcalendar plugin'
            'dillo: for html viewer plugin'
            'gumbo-parser: for litehtml plugin')
source=("https://www.claws-mail.org/releases/${pkgname}-${pkgver}.tar.gz"
        "https://deb.debian.org/debian/pool/main/c/claws-mail/claws-mail_${_debver}-${_debrel}.debian.tar.xz"
        "bash_completion"
        "rework-defs.patch")
sha512sums=('6364415c12170766fbe0b56317308576054f44296d287b568095cf5df53b9da4804633e73c769e5e79d74d70ec2750dce60d9d7cea7c2d4f6dccd6f402de6aa3'
            'e8132f91d116e311e184bfeac2c5b459cfc6b7bfe965952650942d6a2277ed3a5568ce3831930b54615607816ddcb262127ee8863e8a80e1078aad755187a07c'
            '4779669133d077aaa52fc171d693b7ba93208cbc6fee5234550aa3f66ec12e5a5d200aab420ab9ceff65a9509cab3f643280b7b64a35d085d1e64a202d9f7c28'
            '327d4c8f065405108391f7baf9af0c57db8294dc2da3df58cab2031a748414da3a959a51aad78797a61fde541dda30a99be6669f5ba57317b854ff0bc5e66188')

prepare() {
  cd "${pkgname}"-${pkgver}
  if [[ ${pkgver%.*} = ${_debver%.*} ]]; then
    # Debian patches
    export QUILT_PATCHES=debian/patches
    export QUILT_REFRESH_ARGS='-p ab --no-timestamps --no-index'
    export QUILT_DIFF_ARGS='--no-timestamps'

    mv "$srcdir"/debian .

    quilt push -av
  fi
  patch -Np1 -i ${srcdir}/rework-defs.patch
}

build() {
  cd "${pkgname}"-${pkgver}
  ./configure --prefix=/usr --disable-static \
    --enable-enchant \
    --enable-gnutls \
    --enable-ldap \
    --enable-crash-dialog \
    --enable-pgpmime-plugin \
    --enable-bogofilter-plugin \
    --disable-dbus \
    --disable-networkmanager \
    --disable-gdata-plugin \
    --disable-spamassassin-plugin \
    --disable-notification-plugin \
    --disable-fancy-plugin
  sed -i -e 's/ -shared / -Wl,-O1,--as-needed\0/g' libtool
  make
}

package() {
  cd "${pkgname}"-${pkgver}
  make DESTDIR="${pkgdir}" install

  install -Dm 644 "$srcdir"/bash_completion "${pkgdir}"/usr/share/bash-completion/completions/claws-mail

  # license
  install -Dm644 "${srcdir}/${pkgname}-${pkgver}/COPYING" -t "${pkgdir}/usr/share/licenses/$pkgname"
}