# Maintainer: Jesus E. <heckyel@riseup.net>

pkgname=check
pkgver=0.15.2
_debver=$pkgver
_debrel=2
pkgrel=3
pkgdesc="An unit testing framework for C"
url='https://libcheck.github.io/check/'
arch=('i686' 'x86_64')
license=('LGPL-2.1' 'FDL-1.2')
depends=('gawk')
makedepends=('texi2html' 'quilt')
source=("https://github.com/libcheck/check/releases/download/${pkgver}/${pkgname}-${pkgver}.tar.gz"
        "https://deb.debian.org/debian/pool/main/c/check/check_${_debver}-${_debrel}.debian.tar.xz")
sha512sums=('77fb34348bc1b1517801865afee5064121a245c10685e6bb6b8f743552646a0643cfdf9fd3dfbf9b2297d9430dfdd49616cf7daf41298d2dbd699f10d654a025'
            'cd1bdddd6d82829de4ea0a3c2617bbbf19b3c31792f95645662c9182a4b29a4a94fd082137c5ac2118164167cfbd2685c85890b4e0d6a2be8ceedb820e628a51')

prepare() {
  cd $pkgname-$pkgver
  if [[ ${pkgver%.*} = ${_debver%.*} ]]; then
    # Debian patches
    export QUILT_PATCHES=debian/patches
    export QUILT_REFRESH_ARGS='-p ab --no-timestamps --no-index'
    export QUILT_DIFF_ARGS='--no-timestamps'

    mv "$srcdir"/debian .

    # Doesn't apply
    rm -v debian/patches/01pkgconfig.patch || true
    rm -v debian/patches/02awk.patch || true

    quilt push -av
  fi
  autoreconf -fvi
}

build() {
  cd $pkgname-$pkgver
  ./configure \
    --prefix=/usr \
    --disable-static
  make all doc/check_html
}

package() {
  cd $pkgname-$pkgver
  make DESTDIR="$pkgdir" install
  install -Dm644 COPYING.LESSER debian/copyright -t "$pkgdir/usr/share/licenses/$pkgname"
}