# Maintainer: Jesus E. <heckyel@riseup.net>

pkgname=certbot
pkgver=2.11.0
_debver=$pkgver
_debrel=1
pkgrel=1
pkgdesc="ACME client"
arch=('any')
license=('Apache-2.0')
url='https://certbot.eff.org'
depends=('ca-certificates' 'python-acme' 'python-configargparse' 'python-configobj'
         'python-cryptography' 'python-distro' 'python-parsedatetime'
         'python-pyrfc3339' 'python-pytz' 'python-setuptools' 'python-zope-component'
         'python-zope-interface')
makedepends=('quilt')
optdepends=('certbot-nginx: Nginx plugin for Let’s Encrypt client')
source=("https://pypi.io/packages/source/c/$pkgname/${pkgname}-${pkgver}.tar.gz"
        "https://deb.debian.org/debian/pool/main/p/python-certbot/python-certbot_${_debver}-${_debrel}.debian.tar.xz")
sha512sums=('ddc4d92d5b9df8917cf073a0478d85e4dc739160b7f3f6f667df0a119fef8423f0d36e93fcd7972d6e961e44e11eabcf4889c499f9d10388cd6e89eee019bc34'
            '69fa5885ef6fc8f14cc3d36dcfb6e88af7ebe04a01b4a9b08fbcb18cd715f36175e488016f65e43b4d026a579c884bf043b7af8ada4b07ef77377c10c47c93a9')

prepare() {
  cd "$srcdir/$pkgname-$pkgver"
  if [[ ${pkgver%.*} = ${_debver%.*} ]]; then
    # Debian patches
    export QUILT_PATCHES=debian/patches
    export QUILT_REFRESH_ARGS='-p ab --no-timestamps --no-index'
    export QUILT_DIFF_ARGS='--no-timestamps'

    mv "$srcdir"/debian .

    quilt push -av
  fi
}

build() {
  cd "$srcdir/$pkgname-$pkgver"
  python setup.py build
}

package() {
  cd "$srcdir/$pkgname-$pkgver"
  python setup.py install --root="$pkgdir"
  install -d "$pkgdir"/{etc,var/lib,var/log}/letsencrypt
  chmod 700 "$pkgdir"/var/log/letsencrypt
  install -Dm644 LICENSE.txt -t "$pkgdir/usr/share/licenses/$pkgname"
}