# Maintainer: Jesus E. <heckyel@riseup.net>

pkgname=ccache-legacy
_realpkgname=ccache
pkgver=3.7.12
pkgrel=1
pkgdesc="Compiler cache that speeds up recompilation by caching previous compilations (legacy version)"
url='https://ccache.dev/'
arch=('i686' 'x86_64')
license=('GPL-3' 'Modified-BSD' 'zlib' 'Python')
provides=('ccache')
conflicts=('ccache')
depends=('glibc' 'zlib')
source=("https://github.com/${_realpkgname}/${_realpkgname}/releases/download/v${pkgver}/${_realpkgname}-${pkgver}.tar.xz")
sha512sums=('0eb47869f86d36b3e5fad0d5073973f0444f3efe23fd14469a9e05154ea219228443098b1c5e4a8a0c5c78b4bfa7623735b50ebd6b8b4d0626766061850d6a62')

build() {
  cd ${_realpkgname}-${pkgver}
  ./configure \
    --prefix=/usr \
    --sysconfdir=/etc
  make
}

package() {
  cd ${_realpkgname}-${pkgver}

  install -Dm 755 ccache -t "${pkgdir}/usr/bin"
  install -Dm 644 doc/ccache.1 -t "${pkgdir}/usr/share/man/man1"
  install -Dm 644 doc/{AUTHORS,MANUAL,NEWS}.adoc README.md -t "${pkgdir}/usr/share/doc/${_realpkgname}"

  install -d "${pkgdir}/usr/lib/ccache/bin"
  local _prog
  for _prog in gcc g++ c++; do
    ln -s /usr/bin/ccache "${pkgdir}/usr/lib/ccache/bin/$_prog"
    ln -s /usr/bin/ccache "${pkgdir}/usr/lib/ccache/bin/${CHOST}-$_prog"
  done
  for _prog in cc clang clang++; do
    ln -s /usr/bin/ccache "${pkgdir}/usr/lib/ccache/bin/$_prog"
  done

  install -Dm644 LICENSE.adoc GPL-3.0.txt -t "${pkgdir}/usr/share/licenses/$pkgname"
}