# Maintainer: Jesus E. <heckyel@riseup.net>

pkgname=bspwm
pkgver=0.9.10
_debver=$pkgver
_debrel=2
pkgrel=2
pkgdesc="Tiling window manager based on binary space partitioning"
arch=('i686' 'x86_64')
url='https://github.com/baskerville/bspwm'
license=('Simplified-BSD')
depends=('xcb-util' 'xcb-util-wm' 'xcb-util-keysyms')
makedepends=('quilt')
optdepends=('sxhkd: to define keyboard and pointer bindings'
            'xdo: for the example panel')
source=("https://github.com/baskerville/${pkgname}/archive/${pkgver}/${pkgname}-${pkgver}.tar.gz"
        "https://deb.debian.org/debian/pool/main/b/bspwm/bspwm_${_debver}-${_debrel}.debian.tar.xz"
        "libre.patch")
sha512sums=('9ccb98c4e80635a781b3f889d8c3ae621c0926a79e9607268924b78bd11137caf70ee9a1edf5bc137d362d2acbe2984645f58ba31c586e6b017797758a66f9cf'
            '58e1f697102738427f6a391c2de703eedadd7a03b92e7c6da524f76ca7aec612e6f47c489ce8d4b230c582f51f0bde72c3a19b42a8e631a1e45120ef2230116a'
            '39e37a0764e90c5f1d06bf37efa7203c9570ee9172e8445ccd043979f8303cca80663eb42e2c29a0c989694fc37acfacaae9fb2362db15875f0a6f1be0e34d8d')

prepare() {
  cd "$srcdir/$pkgname-$pkgver"
  if [[ ${pkgver%.*} = ${_debver%.*} ]]; then
    # Debian patches
    export QUILT_PATCHES=debian/patches
    export QUILT_REFRESH_ARGS='-p ab --no-timestamps --no-index'
    export QUILT_DIFF_ARGS='--no-timestamps'

    mv "$srcdir"/debian .

    quilt push -av
  fi
  patch -Np1 -i ${srcdir}/libre.patch
}

build() {
  cd "$srcdir/$pkgname-$pkgver"
  make PREFIX=/usr
}

package() {
  cd "$srcdir/$pkgname-$pkgver"
  make PREFIX=/usr DESTDIR="$pkgdir" install
  install -Dm644 LICENSE -t "$pkgdir/usr/share/licenses/$pkgname"
}