# Maintainer: Jesus E. <heckyel@riseup.net>

pkgname=blobby-volley
_realpkgname=blobby2
pkgver=1.0
_debver=$pkgver
_debrel=3.1
pkgrel=1
arch=('i686' 'x86_64')
pkgdesc="A free and libre beach ball game with blobs of goo"
url='https://sourceforge.net/projects/blobby/'
license=('GPL-2')
depends=('sdl2' 'physfs' 'mesa-libgl')
makedepends=('cmake' 'boost' 'mesa' 'zip' 'quilt')
groups=('games')
source=("${pkgname}-${pkgver}.tar.gz::https://downloads.sourceforge.net/blobby/${_realpkgname}-linux-${pkgver}.tar.gz"
        "https://deb.debian.org/debian/pool/main/b/blobby/blobby_${_debver}-${_debrel}.debian.tar.xz"
        "$pkgname.desktop"
        "$pkgname.png")
sha512sums=('b9e36de4a44e482c9d0742b95034c2979d7a51512ac5e3fd8f4933655132028dfc9642c3580e5523b5b95d38acc169932d24808cee236710731c2571321337fa'
            '31a11f59bbcdc58caa07cd5d29fb97813b8c838929e5337974791baaefe24e6c408975a34856e09a302be55ce32be16d58a210bece788006d5bfca9f261482c6'
            '715b4337dc868cf51ca69c01476e1fa3a3dd631397fca91dc55f4d45e241b35dd0850f4be3e12a0afd7c2a94b6adfa623c633d4ce79ca6098f8e7ee6e69b3917'
            '8b7b85d8e02f8174054a724752d5d40c609820be1e5e06c4868dc0e383d4cf4befe73ab0e910e9838b70be3f7e106ee71ef1e04f0560fdde7bff6ca473fa81ec')

prepare() {
  cd "$srcdir"/blobby-$pkgver

  if [[ ${pkgver%.*} = ${_debver%.*} ]]; then
    # Debian patches
    export QUILT_PATCHES=debian/patches
    export QUILT_REFRESH_ARGS='-p ab --no-timestamps --no-index'
    export QUILT_DIFF_ARGS='--no-timestamps'

    mv "$srcdir"/debian .

    # Doesn't apply
    rm -v debian/patches/04_use_system_tinyxml.patch || true
    rm -v debian/patches/02_use_system_lua.patch || true

    quilt push -av
  fi

  sed -i "s|DESTINATION bin|DESTINATION games|g" src/CMakeLists.txt
  sed -i "s|/share/blobby|/share/games/blobby|g" src/main.cpp
}

build() {
  cd "$srcdir"/blobby-$pkgver
  cmake \
    -DCMAKE_INSTALL_PREFIX=/usr
  make
}

package() {
  cd "$srcdir"/blobby-$pkgver

  make DESTDIR="$pkgdir" install

  # correcting wrong folder-locations
  install -dm755 "${pkgdir}/usr/share/games"
  mv "${pkgdir}/usr/share/blobby" "${pkgdir}/usr/share/games"

  # install .desktop file, icon and license
  install -dm755 "$pkgdir"/usr/share/{applications,pixmaps}
  install -m644 "$srcdir"/$pkgname.desktop "$pkgdir"/usr/share/applications
  install -m644 "$srcdir"/$pkgname.png "$pkgdir"/usr/share/pixmaps
  install -Dm644 COPYING -t "${pkgdir}/usr/share/licenses/$pkgname"
}