# Maintainer: Jesus E. <heckyel@riseup.net>

pkgbase=bemenu
pkgname=('bemenu' 'bemenu-ncurses' 'bemenu-x11')
pkgver=0.6.14
pkgrel=1
pkgdesc="Dynamic menu library and client program inspired by dmenu"
url='https://github.com/Cloudef/bemenu'
arch=('i686' 'x86_64')
license=('GPL-3' 'LGPL-3')
makedepends=('ncurses' 'scdoc' 'libxinerama' 'libxkbcommon' 'pango')
source=("https://github.com/Cloudef/bemenu/releases/download/${pkgver}/${pkgname}-${pkgver}.tar.gz"
        "remove-wayland.patch")
sha512sums=('dbcc2f931b9128c1595f11d9ad6d75a03b5b982c43733837db337cbdeb62aab34e962a0a23ba759913bd3d37f5ba369578b7efa309add388a9c3c35b090d7f33'
            '91f36267e51ba27d1e61672797990ef893c1a928b298f790c8fc53bed7a31a647d148ffb4cc97d9c8bcfa6e67dfb511a74a3afd70a7095f767b4ecef9bee402e')

prepare() {
  cd "$pkgbase-$pkgver"
  patch -Np1 -i $srcdir/remove-wayland.patch
}

build() {
  cd "$pkgbase-$pkgver"
  make PREFIX=/usr
}

package_bemenu() {
  depends=(bemenu-renderer)
  provides=(libbemenu)

  cd "$pkgbase-$pkgver"
  make DESTDIR="$pkgdir" PREFIX=/usr install-base install-docs
  install -Dm644 LICENSE-{CLIENT,LIB} -t "$pkgdir/usr/share/licenses/$pkgname"
}

package_bemenu-ncurses() {
  pkgdesc='ncurses renderer for bemenu'
  provides=(bemenu-renderer)
  depends=(libbemenu ncurses)

  cd "$pkgbase-$pkgver"
  make DESTDIR="$pkgdir" PREFIX=/usr install-curses
  install -Dm644 LICENSE-{CLIENT,LIB} -t "$pkgdir/usr/share/licenses/$pkgname"
}

package_bemenu-x11() {
  pkgdesc='X11 renderer for bemenu'
  provides=(bemenu-renderer)
  depends=(libbemenu libxinerama pango)

  cd "$pkgbase-$pkgver"
  make DESTDIR="$pkgdir" PREFIX=/usr install-x11
  install -Dm644 LICENSE-{CLIENT,LIB} -t "$pkgdir/usr/share/licenses/$pkgname"
}