# Maintainer: Jesus E. <heckyel@riseup.net>

pkgname=bchunk
pkgver=1.2.2
_debver=1.2.2
_debrel=2
pkgrel=1
pkgdesc="A Tool to Convert *.raw *.bin files to an ISO file"
url="http://he.fi/bchunk/"
arch=('i686' 'x86_64')
license=('GPL-2')
depends=('glibc')
makedepends=('quilt')
source=(https://deb.debian.org/debian/pool/main/b/bchunk/bchunk_${pkgver}.orig.tar.gz
        https://deb.debian.org/debian/pool/main/b/bchunk/bchunk_${_debver}-${_debrel}.debian.tar.xz)
sha512sums=('94fcc1dea3a38a907b3f209c20f3de54028cc34bf8964d1dccf94faf3ca3851270cc8e052c29a3f04c60e525c029ebfb1c3c04fa85525e20273ac8d72cb317c8'
            '5b38f4c6926842292efc20250bf75103b39d4bfee8b3a6cad67d7eca0cf59dc6bc846d3b28eaa6ad8bbc260a92adc7749406c575944b2638248eeafd445a7872')

prepare() {
  cd "$srcdir/$pkgname-$pkgver"
  if [[ ${pkgver%.*} = ${_debver%.*} ]]; then
    # Debian patches
    export QUILT_PATCHES=debian/patches
    export QUILT_REFRESH_ARGS='-p ab --no-timestamps --no-index'
    export QUILT_DIFF_ARGS='--no-timestamps'

    mv "$srcdir"/debian .

    quilt push -av
  fi
}

build() {
  cd "$srcdir/$pkgname-$pkgver"
  make
}

package() {
  cd "$srcdir/$pkgname-$pkgver"
  install -dm755 "$pkgdir"/usr/{bin,share/man/man1}
  make PREFIX="$pkgdir/usr" MAN_DIR="$pkgdir/usr/share/man" install
  chown root:root "$pkgdir/usr/share/man/man1/bchunk.1"
  install -Dm644 COPYING -t "${pkgdir}/usr/share/licenses/$pkgname"
}