# Maintainer: Jesus E. <heckyel@riseup.net>

pkgname=bc
pkgver=1.07.1
_debver=1.07.1
_debrel=2
pkgrel=2
pkgdesc="An arbitrary precision calculator language"
arch=('i686' 'x86_64')
url="https://www.gnu.org/software/bc/"
license=('LGPL-3')
depends=('readline')
makedepends=('automake-1.14' 'ed' 'quilt')
replaces=('bc-readline')
conflicts=('bc-readline')
source=(https://ftp.gnu.org/gnu/${pkgname}/${pkgname}-${pkgver}.tar.gz{,.sig}
        https://deb.debian.org/debian/pool/main/b/bc/bc_${_debver}-${_debrel}.debian.tar.xz)
sha512sums=('02126d0db6b6ed06d56cfc292d6f5475ff1e574779d7e69c7809bbb1e13f946f57ea07da2a7666baa092507a951a822044b0970075f75eefe65a5c1999b75d34'
            'SKIP'
            '7e4774f072c4bbb7d4d78ab733bd47cb21f274b3e5c2ab0a65a3882e0bdbe39775310ef76cf953433b9e7d6a05455cbd427e0aa91d48a7d44e5e4d043140c93d')
validpgpkeys=('00E426232F384BF6D32D8B1881C24FF12FB7B14B') # Phil Nelson <philnelson@acm.org>

prepare() {
  cd "${pkgname}-${pkgver}"
  if [[ ${pkgver%.*} = ${_debver%.*} ]]; then
    # Debian patches
    export QUILT_PATCHES=debian/patches
    export QUILT_REFRESH_ARGS='-p ab --no-timestamps --no-index'
    export QUILT_DIFF_ARGS='--no-timestamps'

    mv "$srcdir"/debian .

    quilt push -av
  fi
}

build() {
  cd "${pkgname}-${pkgver}"
  ./configure --prefix=/usr --mandir=/usr/share/man \
    --infodir=/usr/share/info --with-readline
  make -j1
}

package() {
  cd "${pkgname}-${pkgver}"
  make DESTDIR="${pkgdir}" install
  install -Dm644 COPYING.LIB -t "$pkgdir"/usr/share/licenses/$pkgname/
}