# Maintainer: Jesus E. <heckyel@riseup.net>

pkgname=awesome
pkgver=4.3
_debver=$pkgver
_debrel=7
pkgrel=2
pkgdesc="Highly configurable framework window manager"
url='https://awesomewm.org/'
arch=('i686' 'x86_64')
license=('GPL-2')
depends=('cairo' 'gdk-pixbuf2' 'imlib2' 'libxdg-basedir' 'lua' 'lua-lgi' 'pango'
         'startup-notification' 'xcb-util-cursor' 'xcb-util-keysyms' 'xcb-util-wm'
         'xenocara-xmessage' 'libxkbcommon-x11' 'libxkbcommon' 'xcb-util-xrm')
makedepends=('asciidoc' 'cmake' 'docbook-xsl' 'doxygen' 'graphicsmagick-imagemagick-compat'
             'quilt' 'ldoc' 'xmlto' 'ttf-font')
backup=('etc/xdg/awesome/rc.lua')
source=("https://github.com/awesomeWM/${pkgname}/releases/download/v${pkgver}/${pkgname}-${pkgver}.tar.xz"
        "https://deb.debian.org/debian/pool/main/a/awesome/awesome_${_debver}-${_debrel}.debian.tar.xz"
        "fix-build.patch")
sha512sums=('c5ef1e8dc593e7783b895d22143154aea8f211beeda24672a7ee4ed5112b4f4284043f848a151f3d3c4f569e91308670367a4353f705b20511b36495b22fa3f5'
            '480ae43c550c78d1f6d3118b5e21cde04b44c2ce55d248e5cb679f241d621d5ad4dab070581c1c86bab2705462a7267dca58d82fbfcd41b770b9f069675478a1'
            '1f0f3c775c12e05b9dcb0108b28ffc88b9263ba46f5dedda1e5db61add40313decb7babca3cda1daf27ada8d88a3295c4fce679fabe3a777ccc148ed2725e11c')

prepare() {
  cd ${pkgname}-${pkgver}
  if [[ ${pkgver%.*} = ${_debver%.*} ]]; then
    # Debian patches
    export QUILT_PATCHES=debian/patches
    export QUILT_REFRESH_ARGS='-p ab --no-timestamps --no-index'
    export QUILT_DIFF_ARGS='--no-timestamps'

    mv "$srcdir"/debian .

    # Doesn't apply
    rm -v debian/patches/debian-customization.patch || true
    rm -v debian/patches/freedesktop-menu.patch || true

    quilt push -av
  fi

  # additional fixes
  patch -Np1 -i "$srcdir/fix-build.patch"
}

build() {
  cmake \
    -S ${pkgname}-${pkgver} \
    -B build \
    -DCMAKE_BUILD_TYPE=RELEASE \
    -DCMAKE_INSTALL_PREFIX=/usr \
    -DSYSCONFDIR=/etc \
    -DLUA_LIBRARY=/usr/lib/liblua5.3.so \
    -DLUA_INCLUDE_DIR=/usr/include
  make -C build
}

package() {
  make -C build DESTDIR="${pkgdir}" install
  install -Dm644 "${srcdir}/${pkgname}-${pkgver}/$pkgname.desktop" -t "${pkgdir}/usr/share/xsessions"
  install -Dm644 "${srcdir}/${pkgname}-${pkgver}/LICENSE" -t "${pkgdir}/usr/share/licenses/${pkgname}"
}