# Maintainer: Jesus E. <heckyel@riseup.net>

pkgname=autogen
pkgver=5.18.16
_debver=$pkgver
_debrel=4
pkgrel=2
pkgdesc="A tool designed to simplify the creation and maintenance of programs that contain large amounts of repetitious text"
arch=('i686' 'x86_64')
url='https://www.gnu.org/software/autogen/'
license=('GPL-3')
depends=('guile' 'libxml2' 'perl')
makedepends=('chrpath' 'quilt')
source=("https://ftp.gnu.org/gnu/${pkgname}/rel${pkgver}/${pkgname}-${pkgver}.tar.xz"
        "https://deb.debian.org/debian/pool/main/a/autogen/autogen_${_debver}-${_debrel}.debian.tar.xz")
sha512sums=('5f12c982dbe27873f5649a96049bf019ff183c90cc0c8a9196556b0ca02e72940cd422f6d6601f68cc7d8763b1124f2765c3b1a6335fc92ba07f84b03d2a53a1'
            'e0157e03501f041d0984062f5db385a4c6aa9789b214eccd6631e0b6131ece9f26976909bbcd18cc0c71d7b63b2b5ea31e75e7cc0b9bc06a5753f6536657a2e1')

prepare() {
  cd $pkgname-$pkgver
  if [[ ${pkgver%.*} = ${_debver%.*} ]]; then
    # Debian patches
    export QUILT_PATCHES=debian/patches
    export QUILT_REFRESH_ARGS='-p ab --no-timestamps --no-index'
    export QUILT_DIFF_ARGS='--no-timestamps'

    mv "$srcdir"/debian .

    quilt push -av
  fi
  autoreconf -vfi
}

build() {
  cd "${srcdir}/${pkgname}-${pkgver}"

  ./configure \
    --prefix=/usr \
    --disable-dependency-tracking

  sed -i -e 's/ -shared / -Wl,-O1,--as-needed\0/g' libtool
  make
}

package() {
  cd "${srcdir}/${pkgname}-${pkgver}"
  make DESTDIR="${pkgdir}" install

  # remove unrequired RPATH from binaries
  for i in ${pkgdir}/usr/bin/*; do
    if chrpath --list "$i"; then
      chrpath --delete "$i";
    fi
  done

  install -Dm644 COPYING -t "$pkgdir/usr/share/licenses/$pkgname"
}