# Maintainer: Jesus E. <heckyel@riseup.net>

_realpkgname=audacious-plugins
pkgname=$_realpkgname-legacy
pkgver=4.2
pkgrel=1
pkgdesc="Plugins for Audacious (legacy version)"
arch=('i686' 'x86_64')
url='https://audacious-media-player.org/'
license=('Simplified-BSD')
depends=('alsa-lib' 'curl' 'faad2' 'ffmpeg' 'flac' 'fluidsynth'
         'jack' 'lame' 'libcdio-paranoia' 'libcue' 'libmms' 'libmodplug'
         'libmtp' 'libsamplerate' 'libvorbis' 'mpg123' 'neon' 'wavpack' 'libbs2b')
makedepends=("audacious-legacy>=$pkgver" 'glib2' 'python' 'gettext-tiny')
source=(https://distfiles.audacious-media-player.org/$_realpkgname-$pkgver.tar.bz2)
sha512sums=('632f1ac90c3a079bb92120e4bc6ef6b13f3f809f150809a64569fae49c908dafeb30e16a34d18bb081e099fe2a252a7ed8b76da129ffa0d51b16216f0b6d1282')

build() {
  cd "$srcdir/$_realpkgname-$pkgver"
  ./configure \
    --prefix=/usr \
    --enable-amidiplug \
    --enable-gtk \
    --enable-lirc=no \
    --enable-mpris2=no
  make
}

package() {
  cd "$srcdir/$_realpkgname-$pkgver"
  make DESTDIR="$pkgdir" install
  install -Dm644 COPYING -t "$pkgdir/usr/share/licenses/$pkgname"
}