# Maintainer: Jesus E. <heckyel@riseup.net>

# Based on aspell-en

_pkgname='aspell'
_pkglang='nl'
_srclang='dutch'
_srcsv=''
pkgname="${_pkgname}-i18n-dict-${_pkglang}"
# Example: _srcname='aspell6-en'
_srcname="${_pkgname}${_srcsv}-${_srclang}"
pkgver='2.20.19.2'
_srcver="2.20.19-2"
pkgrel='2'
pkgdesc='Dutch dictionary for Aspell'
arch=('i686' 'x86_64')
url='https://packages.debian.org/source/bullseye/dutch'
license=('Modified-BSD')
groups=("${_pkgname}-i18n-dict" "${_pkgname}-dict"
        "g${_pkgname}-i18n-dict" "g${_pkgname}-dict"
        "gnu${_pkgname}-i18n-dict" "gnu${_pkgname}-dict"
        "gnu-${_pkgname}-i18n-dict" "gnu-${_pkgname}-dict")
depends=('aspell')
makedepends=('gzip')
provides=("${_pkgname}-dict-${_pkglang}"
          "g${pkgname}" "g${_pkgname}-dict-${_pkglang}"
          "gnu${pkgname}" "gnu${_pkgname}-dict-${_pkglang}"
          "gnu-${pkgname}" "gnu-${_pkgname}-dict-${_pkglang}"
          "${_pkgname}-${_pkglang}")
conflicts=("${_pkgname}-${_pkglang}")
replaces=("${_pkgname}-${_pkglang}")
_source=("http://deb.debian.org/debian/pool/main/${_srclang::1}/${_srclang}")
source=("${_source[0]}/${_srclang}_${_srcver::7}.orig.tar.gz"
        "${_source[0]}/${_srclang}_${_srcver}.diff.gz")
sha512sums=('a8d4ddd77a3ce44ae5b1abef8f7ffe6df2ddc3e0e21f0958c1f36496552db5ca63a303a83d294586bbb7cbc73e6a9bce8808ea5110c18b8b17d98e396aff980e'
            '106edc571737bab8727121c4aa428f508460679ceacce90b9e2c19d02551445453b96a8f5473bf828f5e897954dc309ace068b567ab806421775c54c4fefe22e')
validpgpkeys=()  # The signature file is not found.
unset _pkglang _srcsv _source

prepare() {
  cd "${srcdir}/${_srclang}-${_srcver::7}"
  patch -p '1' -i "${srcdir}/${_srclang}_${_srcver}.diff"
}

package() {
  cd "${srcdir}/${_srclang}-${_srcver::7}"

  for i in 'dutch.alias' 'dutch.multi' 'flemish.multi' 'nederlands.multi' \
      'nl_affix.dat' 'nl.dat' 'nl.multi' 'vlaams.multi'; do
    install -Dm '644' "${_pkgname}/${i}" -t "${pkgdir}/usr/lib/${_pkgname}-0.60"
  done
  unset i

  touch "${pkgdir}/usr/lib/${_pkgname}-0.60/nl.rws"

  grep -av "[0-9 \.'\+]" 'wordlist/wordlist.txt' > "${_pkgname}/nl.wl"
  prezip "${_pkgname}/nl.wl"
  gzip -9nf "${_pkgname}/nl.cwl"
  # word-list-compress 'd' < "${_pkgname}/nl.cwl" | \
  #   aspell --lang='nl' 'create' 'master' "${_pkgname}/nl.rws"

  for i in 'nl.contents' 'nl.cwl.gz'; do
    install -Dm '644' "${_pkgname}/${i}" -t "${pkgdir}/usr/share/${_pkgname}"
  done
  unset i

  for i in 'debian/copyright' 'wordlist/LICENSE.txt'; do
    install -Dm '644' "${i}" -t "${pkgdir}/usr/share/licenses/${pkgname}"
  done
  unset i _pkgname _srclang _srcname _srcver
}